Functions > Keyboard >


SendKeepActive

Tente de garder active une fenêtre spécifiée pendant l'exécution de Send().

SendKeepActive ( "title" [, "text"] )

Paramètres

title Le titre/hWnd/classe de la fenêtre à activer. Consultez Définition spéciale de Titre. Utilisez un titre vide pour désactiver la fonction.
text [optionnel] Le texte de la fenêtre. Par défaut, une chaîne vide. Consultez Définition spéciale de Texte .

Valeur de retour

Succès: Retourne 1.
Échec: Retourne 0 si la fenêtre n'est pas trouvée.

Remarque

L'utilisation de SendKeepActive("") tente de réinitialiser la fenêtre active entre chaque simulation de touche avec Send().

En relation

Send

Exemple

Example()

Func Example()
    ; Exécute le Bloc-notes
    Run("notepad.exe")

    ; Attend 10 secondes pour que la fenêtre du bloc-notes apparaisse.
    Local $hWnd = WinWait("[CLASS:Notepad]", "", 10)

    ; Garde la fenêtre du Bloc-notes active lorsque vous utilisez la fonction Send().
    SendKeepActive("[CLASS:Notepad]")

    ; Simule l'entrée d'une chaîne de texte. Si vous essayez de passer à une autre fenêtre 
    ; que le Bloc-notes, alors la fenêtre du Bloc-notes récupèrera le focus de nouveau.
    For $i = 1 To 10
        Sleep(500)
        Send("notepad - ")
    Next

    ; Désactive la fenêtre du Bloc-notes qui est active lorsque vous utilisez la fonction Send().
    SendKeepActive("")

    ; Ferme la fenêtre du Bloc-notes en utilisant le handle retourné par WinWait.
    WinClose($hWnd)

    ; Maintenant, une fenêtre s'ouvre et demande d'enregistrer les modifications, le nom de classe de la fenêtre est
    ; "#32770" et la simulation de la touche "TAB" pour passer au deuxième bouton dans lequel le "ENTER" est simulé pour ne pas "Enregistrer le fichier"
    WinWaitActive("[CLASS:#32770]")
    Sleep(500)
    Send("{TAB}{ENTER}")
EndFunc   ;==>Example