Functions > FileDirDisk >

IniWrite

Écrit une valeur dans un fichier ini au format standard.

IniWrite ( "filename", "section", "key", "value" )

Paramètres

filename Le nom du fichier ini.
section Le nom de la section dans le fichier ini.
key Le nom de la clé dans le fichier ini.
value La valeur à écrire/modifier.

Valeur de retour

Succès: Retourne 1.
Échec: Retourne 0 si le fichier est en lecture seule.

Remarques

Un fichier .ini standard ressemble à :
[NomdelaSection]
clé=Valeur

Si le fichier n'existe pas, il est créé, dans la mesure où le répertoire existe. Les clés et/ou les sections sont ajoutées à la fin et ne sont pas triées.

Lorsque vous écrivez une valeur qui est entre guillemets, les guillemets sont supprimés. Pour pouvoir écrire des guillemets dans la valeur, vous devez mettre des doubles guillemets entouré par des simple guillemets. Par exemple : ""Ceci est un test"" va produire "Ceci est un test" lors de l'utilisation de IniRead() ou semblable.

Les espaces de début et de fin sont supprimés. Pour conserver les espaces, la chaîne de caractère doit être entre guillemets. Par exemple, " ceci est un test" préservera les espaces, mais comme vu plus haut les guillemets seront supprimés.

Une valeur sur plusieurs lignes n'est pas possible.

Si vous desirez utiliser un fichier ini avec un encodage Unicode, premièrement créez un fichier .ini en utilisant la fonction FileOpen() avec le paramètre de mode positionné sur Unicode.

En relation

IniDelete, IniRead, IniReadSection, IniReadSectionNames, IniRenameSection, IniWriteSection

Exemple

#include <MsgBoxConstants.au3>
#include <WinAPIFiles.au3>

Example()

Func Example()
    ; Crée une constante locale avec le nom complet du fichier qui sera lu/écrit
    Local Const $sFilePath = _WinAPI_GetTempFileName(@TempDir)

    ; Ecrit la valeur de 'AutoIt' à la clé "Title" et dans la section "General".
    IniWrite($sFilePath, "General", "Title", "AutoIt")

    ; Lit la valeur correspondante à la clé 'Title' dans la section 'General'.
    Local $sRead = IniRead($sFilePath, "General", "Title", "Default Value")

    ; Affiche la valeur retournée par IniRead.
    MsgBox($MB_SYSTEMMODAL, "", "La valeur correspondante à la clé 'Title' dans la section  'General' est: " & $sRead)

    ; Supprime la clé 'Title'.
    IniDelete($sFilePath, "General", "Title")

    ; Lit le fichier INI pour la valeur de 'Title' dans la section 'General'.
    $sRead = IniRead($sFilePath, "General", "Title", "Default Value")

    ; Affiche la valeur retournée par IniRead. Comme il n'y a pas de clé stocké la valeur sera la 'Valeur par défaut' passée à IniRead.
    MsgBox($MB_SYSTEMMODAL, "", "La valeur correspondante à la clé 'Title' dans la section  'General' est: : " & $sRead)

    ; Supprime le fichier INI.
    FileDelete($sFilePath)
EndFunc   ;==>Example