Functions > FileDirDisk >


IniRenameSection

Renomme une section dans un fichier ini au format standard.

IniRenameSection ( "filename", "section", "new section" [, flag = 0] )

Paramètres

filename Le nom complet du fichier ini.
section Le nom de la section à renommer dans le fichier ini.
new section Le nouveau nom de la section.
flag [optionnel]
    $FC_NOOVERWRITE(0) = (par défaut) Échoue si "new section" existe déjà.
    $FC_OVERWRITE(1) = Remplace "new section". Cela effacera toutes les clés existantes dans "new section"

Valeur de retour

Succès: Retourne une valeur non nulle.
Échec: Retourne 0 et définit @error <> 0, si le renommage a échoué parce que la section existe déjà (seulement lorsque flag = 0).

Remarque

Un fichier ini standard ressemble à :
[ SectionName]
Key = valeur

En relation

IniDelete, IniRead, IniReadSection, IniReadSectionNames, IniWrite, IniWriteSection

Exemple

#include <MsgBoxConstants.au3>
#include <WinAPIFiles.au3>

Example()

Func Example()
    ; Crée une constante locale avec le nom complet du fichier qui sera lu/écrit
    Local Const $sFilePath = _WinAPI_GetTempFileName(@TempDir)

    ; Crée une structure de section INI sous forme de chaîne.
    Local $sSection = "Title=AutoIt" & @CRLF & "Version=" & @AutoItVersion & @CRLF & "OS=" & @OSVersion

    ; Écrit la chaîne dans les sections 'General', 'Version' et 'Other'.
    IniWriteSection($sFilePath, "General", $sSection)
    IniWriteSection($sFilePath, "Version", $sSection)
    IniWriteSection($sFilePath, "Other", $sSection)

    ; Renomme la section 'General' en 'System'.
    IniRenameSection($sFilePath, "General", "System")

    ; Lit les noms des sections INI. Ce qui retourne un tableau à 1 dimension.
    Local $aArray = IniReadSectionNames($sFilePath)

    ; Vérifie si une erreur s'est produite.
    If Not @error Then
        ; Énumére le tableau où figurent les noms des sections.
        For $i = 1 To $aArray[0]
            MsgBox($MB_SYSTEMMODAL, "", "Section: " & $aArray[$i])
        Next
    EndIf

    ; Supprime le fichier INI.
    FileDelete($sFilePath)
EndFunc   ;==>Example