Functions > FileDirDisk >


IniDelete

Supprime une valeur à partir d'un fichier .ini au format standard.

IniDelete ( "filename", "section" [, "key"] )

Paramètres

filename Nom du fichier .ini.
section Nom de la section dans le fichier .ini.
key [optionnel] Nom de la clé à supprimer dans le fichier .ini. Si le nom de la clé n'est pas donné, la section entière sera supprimée. Le mot-clé "Default" peut aussi être utilisé pour supprimer la section.

Valeur de retour

Succès: Retourne 1.
Échec: Retourne 0 si le fichier .ini n'existe pas ou s'il est en lecture seule.

Remarque

Un fichier .ini standard est de la forme :
[Nom_De_La_Section]
Clé=Valeur

En relation

IniRead, IniReadSection, IniReadSectionNames, IniRenameSection, IniWrite, IniWriteSection

Exemple

#include <MsgBoxConstants.au3>
#include <WinAPIFiles.au3>

Example()

Func Example()
    ; Crée une constante locale avec le nom complet du fichier qui sera lu/écrit
    Local Const $sFilePath = _WinAPI_GetTempFileName(@TempDir)

    ; Ecrit la valeur de 'AutoIt' à la clé "Title" et dans la section "General".
    IniWrite($sFilePath, "General", "Title", "AutoIt")

    ; Lit la valeur correspondante à la clé 'Title' dans la section 'General'.
    Local $sRead = IniRead($sFilePath, "General", "Title", "Default Value")

    ; Affiche la valeur retournée par IniRead.
    MsgBox($MB_SYSTEMMODAL, "", "La valeur correspondante à la clé 'Title' dans la section  'General' est: " & $sRead)

    ; Supprime la clé 'Title'.
    IniDelete($sFilePath, "General", "Title")

    ; Lit le fichier INI pour la valeur de 'Title' dans la section 'General'.
    $sRead = IniRead($sFilePath, "General", "Title", "Default Value")

    ; Affiche la valeur retournée par IniRead. Comme il n'y a pas de clé stocké la valeur sera la 'Valeur par défaut' passée à IniRead.
    MsgBox($MB_SYSTEMMODAL, "", "La valeur correspondante à la clé 'Title' dans la section  'General' est: : " & $sRead)

    ; Supprime le fichier INI.
    FileDelete($sFilePath)
EndFunc   ;==>Example