Functions > GUI > GUISetParameters >


GUISetStyle

Modifie les styles d'une fenêtre GUI.

GUISetStyle ( Style [, ExStyle [, winhandle]] )

Paramètres

style Définit le style de la fenêtre. Voir l'annexe Styles des contrôles GUI.
Utilisez -1 pour laisser inchangé.
exStyle [optionnel] Définit le style étendu de la fenêtre. Voir le Table des Styles Etendus. -1 est la valeur par défaut.
Utilisez -1 pour laisser inchangé.
winhandle [optionnel] Handle Windows retourné par GUICreate() (par défaut, la fenêtre précédemment utilisée ).

Valeur de retour

Succès: Retourne 1.
Échec: Retourne 0.

Remarque

Aucune vérification n'est effectuée sur la valeur du style, pas plus que sur l'interaction avec contrôle déjà défini. Il est de la responsabilité du concepteur d'assurer cette compatibilité.

En relation

GUIGetStyle

Exemple

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Example()

Func Example()

    GUICreate("Gui Style", 260, 100)
    Local $idButton = GUICtrlCreateButton("Set Style", 45, 50, 150, 20)
    GUISetState(@SW_SHOW)

    Local $bNewStyle = False, $idMsg
    Do
        $idMsg = GUIGetMsg()
        If $idMsg = $idButton Then
            If Not $bNewStyle Then
                GUISetStyle(BitOR($WS_POPUPWINDOW, $WS_THICKFRAME), BitOR($WS_EX_CLIENTEDGE, $WS_EX_TOOLWINDOW))
                GUICtrlSetData($idButton, 'Undo Style')
            Else
                GUISetStyle(BitOR($WS_MINIMIZEBOX, $WS_CAPTION, $WS_POPUP, $WS_SYSMENU), 0)
                GUICtrlSetData($idButton, 'Set Style')
            EndIf
            $bNewStyle = Not $bNewStyle
        EndIf
    Until $idMsg = $GUI_EVENT_CLOSE

    GUIDelete()
EndFunc   ;==>Example