Functions > Window > Controls >

ControlGetText

Obtient le texte d'un contrôle.

ControlGetText ( "title", "text", controlID )

Paramètres

title Le titre/hWnd/class de la fenêtre à atteindre. Consultez Définition spéciale de titre.
text Le texte de la fenêtre à atteindre. Consultez Définition spéciale de texte.
controlID Le contrôle avec lequel interagir. Consultez Controls.

Valeur de retour

Succès: Retourne le texte d'un contrôle.
Échec: Retourne "" (chaine vide) et @error = 1.

En relation

ControlCommand, ControlSetText, StatusbarGetText, WinGetText

Exemple

#include <MsgBoxConstants.au3>

Example()

Func Example()
    ; Exécute le Bloc-notes
    Run("notepad.exe")

    ; Attend 10 secondes pour que la fenêtre du Bloc-notes apparaisse.
    Local $hWnd = WinWait("[CLASS:Notepad]", "", 10)

    ; Définit le texte du contrôle d'édition du Bloc-notes. Le handle retourné par WinWait est utilisé pour le paramètre "titre" de ControlSetText.
    ControlSetText($hWnd, "", "Edit1", "Ceci est un peu de texte")

    ; Obtient le texte du contrôle d'édition du Bloc-notes. Le handle retourné par WinWait est utilisé pour le paramètre "titre" de ControlGetText.
    Local $sText = ControlGetText($hWnd, "", "Edit1")

    ; Affiche le texte du contrôle d'édition.
    MsgBox($MB_SYSTEMMODAL, "", "Le texte dans Edit1 est: " & $sText)

    ; Ferme la fenêtre du Bloc-notes en utilisant le handle retourné par WinWait.
    WinClose($hWnd)
EndFunc   ;==>Example