Functions > Misc >


AutoItWinSetTitle

Modifie le titre d'une fenêtre Autoit.

AutoItWinSetTitle ( "newtitle" )

Paramètre

newtitle Le nouveau titre à donner à la fenêtre.

Valeur de retour

Aucune.

Remarque

La fenêtre Autoit est habituellement cachée. L'intérêt de changer son titre est d'autoriser d'autres programmes (ou d'autres scripts Autoit) à interagir avec Autoit.

En relation

AutoItWinGetTitle, WinSetTitle

Exemples

Exemple 1

; Vérifie si le script est déjà en cours d'exécution
; Remarque: L'approche recommandée est d'utiliser _Singleton de Misc.au3

#include <MsgBoxConstants.au3>

Local $sMyAutoItTitle = "ThisIsSomeUniqueStringThatOtherWindowsWontHave"

If WinExists($sMyAutoItTitle) Then
    ; Le script est déjà en cours d'exécution

    MsgBox($MB_SYSTEMMODAL, Default, "Le script est déjà en exécution." & @CRLF & @CRLF & _
            "Son PID est: " & WinGetProcess($sMyAutoItTitle))
Else
    ; Il sagit de la première instance du script.

    ;Définit le titre de la fenêtre AutoIt
    AutoItWinSetTitle($sMyAutoItTitle)

    ; Exécute de nouveau ce script.
    If @Compiled Then
        Run('"'& @ScriptFullPath & '"')
    Else
        Run('"'& @AutoItExe & '" "'& @ScriptFullPath & '"')
    EndIf

    MsgBox($MB_SYSTEMMODAL, Default, "Ceci est la première instance." & @CRLF & @CRLF & _
            "Mon PID est: " & @AutoItPID)
EndIf

Exemple 2

#include <GUIConstantsEx.au3>

Example()

Func Example()
    ; Définit le titre de la fenêtre cachée AutoIt.
    AutoItWinSetTitle("My AutoIt Window")

    ; Affiche la fenêtre cachée de AutoIt.
    AutoItWinShow()

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Affiche la fenêtre cachée de AutoIt. Retourne le handle de la fenêtre.
Func AutoItWinShow()
    ; Obtient le handle de la fenêtre cachée AutoIt à partir du titre de la fenêtre cachée AutoIt.
    Local $hWnd = WinGetHandle(AutoItWinGetTitle())

    ; Déplace la fenêtre cachée AutoIt et la redimensionne pour une meilleure vue.
    WinMove($hWnd, "", (@DesktopWidth / 2) - 250, (@DesktopHeight / 2) - 250, 500, 500)

    ; Montre la fenêtre cachée de AutoIt, normalement elle est cachée, mais dans l'intérêt de cet exemple, je la montre.
    WinSetState($hWnd, "", @SW_SHOW)

    Return $hWnd
EndFunc   ;==>AutoItWinShow