UDF > Sound >


_SoundPause

Met en pause un fichier son qui est en train d'être joué

#include <Sound.au3>
_SoundPause ( $aSndID )

Paramètre

$aSndId Tableau d'identification du son retourné par _SoundOpen() ou un nom de fichier

Valeur de retour

Succès: Retourne 1.
Échec: Retourne 0 et définit @error <> 0.
@error: 1 = La pause a échouée
3 = Identification invalide du son. Utiliser le tableau retourné par _SoundOpen() ou un nom de fichier valide.

En relation

_SoundOpen, _SoundPlay, _SoundResume

Exemple

#include <MsgBoxConstants.au3>
#include <Sound.au3>

Local $aSound = _SoundOpen(@WindowsDir & "\media\tada.wav")
If @error = 2 Then
    MsgBox($MB_SYSTEMMODAL, "Erreur", "Le fichier n'existe pas.")
    Exit
ElseIf @extended <> 0 Then
    Local $iExtended = @extended ; Parce que @extended sera défini après DllCall.
    Local $tText = DllStructCreate("char[128]")
    DllCall("winmm.dll", "short", "mciGetErrorStringA", "str", $iExtended, "ptr", DllStructGetPtr($tText), "int", 128)
    MsgBox($MB_SYSTEMMODAL, "Erreur", "L'ouverture a échoué." & @CRLF & "Numéro de l'erreur: " & $iExtended & @CRLF & "Description de l'erreur: " & DllStructGetData($tText, 1) & @CRLF & "Notez SVP: Le son peut encore jouer correctement.")
Else
    MsgBox($MB_SYSTEMMODAL, "Succès", "Le fichier a été ouvert avec succès.")
EndIf
_SoundPlay($aSound)
Sleep(1000)

_SoundPause($aSound)
Sleep(1000)

_SoundResume($aSound)

Do
    Sleep(100)
Until _SoundPos($aSound, 2) >= _SoundLength($aSound, 2)

_SoundClose($aSound)