UDF > Sound >

_SoundPlay

Joue un fichier son

#include <Sound.au3>
_SoundPlay ( $aSndID [, $iWait = 0] )

Paramètres

$aSndID Tableau d'identification du son retourné par _SoundOpen() ou le nom du fichier
$iWait [optionnel] Cet indicateur détermine si le script doit attendre que le son soit terminé avant de poursuivre :
    0 = le script continue pendant que le son joue (par défaut)
    1 = attend que le son soit terminé pour continuer

Valeur de retour

Succès: Retourne 1.
Échec: Retourne 0 et définit @error <> 0.
@error: 1 = La lecture du son a échouée
2 = le paramètre $iWait est invalide
3 = ID du son invalide. Utiliser le tableau retourné par _SoundOpen() ou un nom de fichier valide.

Remarque

Sous Windows Vista ou une version ultérieure, les fichiers "\Windows\Media\..." contenant des espaces doivent être ouverts avec _SoundOpen() avant d'utiliser cette fonction avec le tableau d'ID du son retourné.

En relation

_SoundOpen, _SoundPause, _SoundResume, _SoundSeek, _SoundStop

Exemple

#include <MsgBoxConstants.au3>
#include <Sound.au3>

Local $aSound = _SoundOpen(@WindowsDir & "\media\tada.wav")
If @error = 2 Then
    MsgBox($MB_SYSTEMMODAL, "Error", "Le fichier n'existe pas.")
    Exit
ElseIf @extended <> 0 Then
    Local $iExtended = @extended ; Parce que @extended sera défini après DllCall.
    Local $tText = DllStructCreate("char[128]")
    DllCall("winmm.dll", "short", "mciGetErrorStringA", "str", $iExtended, "ptr", DllStructGetPtr($tText), "int", 128)
    MsgBox($MB_SYSTEMMODAL, "Erreur", "L'ouverture a échoué." & @CRLF & "Numéro de l'erreur: " & $iExtended & @CRLF & "Description de l'erreur: " & DllStructGetData($tText, 1) & @CRLF & "Notez SVP: Le son peut toujours jouer correctement.")
Else
    MsgBox($MB_SYSTEMMODAL, "Succès", "L'ouverture du fichier a réussi.")
EndIf

_SoundPlay($aSound, 1)

_SoundClose($aSound)