UDF > Sound >

_SoundLength

Retourne la durée du fichier son

#include <Sound.au3>
_SoundLength ( $aSndID [, $iMode = 1] )

Paramètres

$aSndID Tableau d'identification du son retourné par _SoundOpen() ou le nom de fichier
$iMode [optionnel] Cet indicateur détermine le format de la durée du son retourné
    1 = (par défaut) hh:mm:ss où h = heures, m = minutes et s = secondes
    2 = millisecondes

Valeur de retour

Succès: Retourne la durée du son.
Échec: Retourne 0 et définit @error <> 0.
@error: 1 = $iMode est invalide
3 = ID du son invalide. Utiliser le tableau de retourné par _SoundOpen() ou un nom de fichier valide.

Remarque

Cette fonction retourne la meilleure valeur disponible pour la durée du fichier en fonction de la méthode d'encodage ou du type de paramètre.

En relation

_SoundOpen, _SoundPos

Exemple

#include <MsgBoxConstants.au3>
#include <Sound.au3>

Local $aSound = _SoundOpen(@WindowsDir & "\media\tada.wav")
If @error = 2 Then
    MsgBox($MB_SYSTEMMODAL, "Error", "Le fichier n'xiste pas!")
    Exit
ElseIf @extended <> 0 Then
    Local $iExtended = @extended ; Parce que @extended sera défini après DllCall.
    Local $tText = DllStructCreate("char[128]")
    DllCall("winmm.dll", "short", "mciGetErrorStringA", "str", $iExtended, "ptr", DllStructGetPtr($tText), "int", 128)
    MsgBox($MB_SYSTEMMODAL, "Erreur", "L'ouverture a échoué." & @CRLF & "Numéro de l'erreur: " & $iExtended & @CRLF & "Description de l'erreur: " & DllStructGetData($tText, 1) & @CRLF & "Notez SVP: Le son peut toujours jouer correctement.")
Else
    MsgBox($MB_SYSTEMMODAL, "Succès", "L'ouverture du fichier a réussi")
EndIf

MsgBox($MB_SYSTEMMODAL, "Longueur du son", "Le son a une longueur de:" & @CRLF & "hh:mm:ss - " & _
        _SoundLength($aSound, 1) & @CRLF & "Millisecondes - " & _SoundLength($aSound, 2))