UDF > Clipboard >


_ClipBoard_SetDataEx

Place des données dans le presse-papiers dans un format spécifié de presse-papiers

#include <Clipboard.au3>
_ClipBoard_SetDataEx ( ByRef $hMemory [, $iFormat = 1] )

Paramètres

$hMemory Handle des données dans le format spécifié. Ce paramètre peut être NULL, ce qui indique que la fenêtre fournit des données dans le format spécifié du presse-papiers sur demande.
Si une fenêtre retarde à s'afficher, elle doit traiter les messages $WM_RENDERFORMAT et $WM_RENDERALLFORMATS.
Si cette fonction réussit, le système s'approprie l'objet identifié par le paramètre $hMEMORY.
L'application ne peut écrire ou libérer les données une fois que la propriété a été transférée au système, mais elle peut verrouiller et lire les données jusqu'à ce que la fonction _ClipBoard_Close() soit appelée.
La mémoire doit être déverrouillée avant que le presse-papiers soit fermé.
Si le paramètre $hMEMORY identifie un objet mémoire, l'objet doit avoir été alloué à l'aide de la fonction avec le flag $GMEM_MOVEABLE.
$iFormat [optionnel] Spécifie un format de presse-papiers:
$CF_TEXT - Format texte
$CF_BITMAP - Handle d'une image bitmap (HBITMAP)
$CF_METAFILEPICT - Handle d'un métafichier d'image (METAFILEPICT)
$CF_SYLK - Format Microsoft Symbolic Link (SYLK)
$CF_DIF - Format Data Interchange de Software Arts
$CF_TIFF - Format Tagged Image File
$CF_OEMTEXT - Format texte contenant des caractères dans le jeu de caractères OEM
$CF_DIB - Structure de BITMAPINFO suivie par les bits du bitmap
$CF_PALETTE - Handle d'une palette de couleurs
$CF_PENDATA - Données pour les extensions de crayon à Pen Computing
$CF_RIFF - Représente les données audio au format RIFF
$CF_WAVE - Représente les données audio au format WAVE
$CF_UNICODETEXT - Format texte Unicode
$CF_ENHMETAFILE - Handle d'un métafichier étendu (HENHMETAFILE)
$CF_HDROP - Handle d'un type HDROP qui identifie une liste de fichiers
$CF_LOCALE - Handle d'un identifiant de paramètres régionaux associés au texte du presse-papiers
$CF_DIBV5 - Structure BITMAPV5HEADER suivie par les couleurs du bitmap et des bits du bitmap
$CF_OWNERDISPLAY - Format d'affichage propriétaire
$CF_DSPTEXT - Format d'affichage de texte associé à un format privé
$CF_DSPBITMAP - Format d'affichage de bitmap associé à un format privé
$CF_DSPMETAFILEPICT - Format d'affichage de métafichier d'image associé à un format privé
$CF_DSPENHMETAFILE - Format d'affichage de métafichier amélioré associé à un format privé

Valeur de retour

Succès: Retourne le handle des données
Échec: Retourne 0

Remarque

Le paramètre $iFormat peut identifier un format de presse-papiers enregistré, ou il peut être l'un des formats standards du presse-papiers.
Si une application appelle cette fonction en réponse à $WM_RENDERFORMAT ou $WM_RENDERALLFORMATS, l'application ne doit pas utiliser le handle après que cette fonction ait été appelée.
Si une application appelle _ClipBoard_Open() avec un handle NULL, _ClipBoard_Empty() définit le propriétaire du presse-papiers à NULL; ce qui fait échouer la fonction.

En relation

_ClipBoard_Empty, _ClipBoard_GetData, _ClipBoard_Open, _ClipBoard_SetData

Voir aussi

Consultez SetClipboardData dans la Librairie MSDN.

Exemple

#include <Clipboard.au3>
#include <GUIConstantsEx.au3>
#include <Memory.au3>
#include <WinAPIError.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $id_SetData, $id_GetData, $hMemory, $hLock, $tData, $sData, $iSize

    ; Créer une GUI
    GUICreate("Clipboard", 600, 450)
    $g_idMemo = GUICtrlCreateEdit("", 2, 2, 596, 396, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    $id_SetData = GUICtrlCreateButton("Set ClipBoard Data", 150, 410, 120, 30)
    $id_GetData = GUICtrlCreateButton("Get ClipBoard Data", 300, 410, 120, 30)
    GUISetState(@SW_SHOW)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Local $iMsg = GUIGetMsg()

    While $iMsg <> $GUI_EVENT_CLOSE 
        Switch $iMsg
            Case $id_SetData
                ; Ouvrir le presse-papiers
                If _ClipBoard_Open(0) Then

                    ; Presse-papiers vide
                    If _ClipBoard_Empty() Then

                        ; Crée tampon de mémoire global (montre pourquoi l'utilisation de _ClipBoard_SetData est beaucoup plus facile!)
                        $sData = "Hello from AutoIt"
                        $iSize = StringLen($sData) + 1
                        $hMemory = _MemGlobalAlloc($iSize, $GHND)
                        If $hMemory <> 0 Then
                            $hLock = _MemGlobalLock($hMemory)
                            If $hLock = 0 Then _WinAPI_ShowError("_Mem_GlobalLock a échoué")
                            $tData = DllStructCreate("char Text[" & $iSize & "]", $hLock)
                            DllStructSetData($tData, "Text", $sData)
                            _MemGlobalUnlock($hMemory)

                            ; Ecrit du texte dans le presse-papiers
                            If Not _ClipBoard_SetDataEx($hMemory, $CF_TEXT) Then _WinAPI_ShowError("_ClipBoard_SetDataEx failed")
                        Else
                            _WinAPI_ShowError("_Mem_GlobalAlloc a échoué")
                        EndIf

                        ; Ferme le presse-papiers
                        _ClipBoard_Close()
                    Else
                        ; Ferme le presse-papiers
                        _ClipBoard_Close()
                        _WinAPI_ShowError("_ClipBoard_Empty a échoué")
                    EndIf
                Else
                    _WinAPI_ShowError("_ClipBoard_Open a échoué")
                EndIf

            Case $id_GetData
                MemoWrite(_ClipBoard_GetData())
        EndSwitch
        $iMsg = GUIGetMsg()
    WEnd
EndFunc   ;==>Example

; Ecrit un message dans memo
Func MemoWrite($sMessage = "")
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite