UDF > Clipboard >

_ClipBoard_Close

Ferme le presse-papiers

#include <Clipboard.au3>
_ClipBoard_Close ( )

Valeur de retour

Succès: Retourne True
Échec: Retourne False

Remarque

Lorsque la fenêtre a fini d'examiner ou de modifier le presse-papiers, fermez le presse-papiers en appelant cette fonction.
Cela permet à d'autres fenêtres d'accéder au presse-papiers. Ne placez pas d'objet dans le presse-papiers après l'appel de cette fonction.

En relation

_ClipBoard_Open

Voir aussi

Consultez CloseClipboard dans la Librairie MSDN.

Exemple

#include <Clipboard.au3>
#include <GUIConstantsEx.au3>
#include <WinAPIError.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $hGUI

    ; Crée une GUI
    $hGUI = GUICreate("Clipboard", 600, 400)
    $g_idMemo = GUICtrlCreateEdit("", 2, 2, 596, 396, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Ouvre le presse-papiers
    If Not _ClipBoard_Open($hGUI) Then _WinAPI_ShowError("_ClipBoard_Open failed")

    ; Affiche les formats disponibles du presse-papiers
    MemoWrite("Clipboard formats ..: " & _ClipBoard_CountFormats())

    ; Vide le presse-papiers
    If Not _ClipBoard_Empty() Then _WinAPI_ShowError("_ClipBoard_Empty failed")

    ; Affiche les formats disponibles du presse-papiers
    MemoWrite("Clipboard formats ..: " & _ClipBoard_CountFormats())

    ; Ferme le presse-papiers
    _ClipBoard_Close()

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Ecrit un message dans le contrôle memo
Func MemoWrite($sMessage = "")
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite