UDF > Clipboard >


_ClipBoard_Empty

Vide le presse-papiers et libère les handles des données du presse-papiers

#include <Clipboard.au3>
_ClipBoard_Empty ( )

Valeur de retour

Succès: Retourne True
Échec: Retourne False

Remarque

Avant d'appeler cette fonction, vous devez ouvrir le presse-papiers en utilisant la fonction _ClipBoard_Open().
Si vous avez spécifié un handle de fenêtre NULL lors de l'ouverture du presse-papiers, cette fonction réussit mais définit le propriétaire du presse-papiers comme NULL.
A noter que cela provoque l'échec de la fonction _ClipBoard_SetData().

En relation

_ClipBoard_GetOwner, _ClipBoard_Open, _ClipBoard_SetData, _ClipBoard_SetDataEx

Voir aussi

Consultez EmptyClipboard dans la Librairie MSDN.

Exemple

#include <Clipboard.au3>
#include <GUIConstantsEx.au3>
#include <WinAPIError.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $hGUI

    ; Crée une GUI
    $hGUI = GUICreate("Clipboard", 600, 400)
    $g_idMemo = GUICtrlCreateEdit("", 2, 2, 596, 396, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Ouvre le presse-papiers
    If _ClipBoard_Open($hGUI) Then
        ShowData($hGUI)

        ; Vide le presse-papiers
        If Not _ClipBoard_Empty() Then _WinAPI_ShowError("_ClipBoard_Empty failed")

        ; Ferme le presse-papiers
        _ClipBoard_Close()
    Else
        _WinAPI_ShowError("_ClipBoard_Open failed")
    EndIf

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Affiche les statistiques du presse-papiers
Func ShowData($hGUI)
    MemoWrite("GUI handle ............: " & $hGUI)
    MemoWrite("Clipboard owner .......: " & _ClipBoard_GetOwner())
    MemoWrite("Clipboard open window .: " & _ClipBoard_GetOpenWindow())
    MemoWrite("Clipboard sequence ....: " & _ClipBoard_GetSequenceNumber())
    MemoWrite()
EndFunc   ;==>ShowData

; Ecrit un message dans le contrôle memo
Func MemoWrite($sMessage = "")
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite