[R] GUICtrlSetBkColor clignotant

[Kagami]

Mouais... Bon le titre est pas très explicite donc je vais essayer d'être assez précis.

Alors alors, j'ai un Label au dimension d'un trait assez large et qui est colorisé par GUICtrlSetBkColor
En gros, ça donne un trait de couleur.

Ce que je voudrais faire, c'est mettre dans une fonction que lorsque l'on a bon, le label passe du rouge au vert pendant environ une seconde et redevienne rouge.
En gros, il ferait un clignotement vert visible à l’œil.

J'ai essayé avec un Sleep mais, vous vous en doutez certainement, ça met tout le script en pause et donc ça casse tout mon programme (qui n'est pas le mien puisque je ne fait qu'améliorer la base d'un autre).

Voilà, si quelqu'un a une solution pour changer la couleur d'un label pendant X temps ce serait sympathique =)
Merci à vous.

[Tlem]

Un truc dans ce genre là ?

► Afficher le texte

Code : Tout sélectionner

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>

Global $iID

GUICreate("Ma GUI", 272, 155, 192, 124)
Global $MonLabel = GUICtrlCreateLabel("Mon Label", 56, 24, 162, 41)
GUICtrlSetFont(-1, 24, 800, 0, "MS Sans Serif")
GUICtrlSetColor(-1, 0xFF0000)

Global $Go = GUICtrlCreateButton("Go", 88, 120, 75, 25)
GUISetState(@SW_SHOW)

While 1
 $nMsg = GUIGetMsg()
 Switch $nMsg
  Case $GUI_EVENT_CLOSE
   Exit

   Case $Go
       $iID = $MonLabel
      _Green()

 EndSwitch
WEnd

Func _Green()
    GUICtrlSetColor($iID, 0x00FF00)
    AdlibRegister("_Red", 1000)
EndFunc

Func _Red()
    GUICtrlSetColor($iID, 0xFF0000)
    AdlibUnRegister("_Red")
EndFunc

[Kagami]

Hum... Oui c'est ça mais j'ai un petit problème =d
Déjà, suis-je obligé de passer par $iID parce qu'au final ça fait juste déclarer une variable qui est une autre variable donc c'est peut-être pas utile?

Bref, je vais vous donner la source que je n'ai que fait de reprendre du travail de Mikell à ce sujet: http://autoitscript.fr/forum/viewtopic.php?f=20&t=8398

J'ai simplement refait l'interface (Que je remplacerai plus tard par une faite sous PhotoShop) et je suis en train d'améliorer le script pour qu'il propose plus de fonctions.

► Afficher le texte

Code : Tout sélectionner

;===Includes===
#include <ButtonConstants.au3>
#include <ComboConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <Array.au3>
#include <Misc.au3>


;===Déclaration des variables===
Global $Key, $Reussis = -1, $Echoues = 0
Dim $Labels[1]
Global $String = "azertyuiopqsdfghjklmwxcvbn"

;==Réglages==
Global $VitesseCreationLettres = 500 ;Facile=1200  Moyen=800  Difficile=400  Expert=500
Global $VitesseDescente = 200 ;Facile=800  Moyen=600  Difficile=400  Expert=200


;===GUI===
#Region ### START Koda GUI section ### Form=
;=Fenêtre=
$GUI = GUICreate("TouchKeyPro 1", 391, 410, 638, 233)
;=Titre=
$LabelTitre = GUICtrlCreateLabel("Touch Key Pro 1", 8, 8, 378, 57)
GUICtrlSetFont(-1, 36, 800, 0, "OptimusPrinceps")
;=Barres de jeu=
$BarreBas = GUICtrlCreateLabel("", 0, 306, 390, 4)
GUICtrlSetBkColor(-1, 0xFF0000)
$BarreHaut = GUICtrlCreateLabel("", 0, 66, 390, 4)
GUICtrlSetBkColor(-1, 0xFF0000)
;=Groupe Score=
$GroupScore = GUICtrlCreateGroup("Score", 8, 320, 113, 65)
GUICtrlCreateLabel("Coups Réussis", 16, 336, 74, 17)
GUICtrlSetColor(-1, 0x008000)
$CoupsReussis = GUICtrlCreateLabel("", 95, 336, 20, 17)
GUICtrlCreateLabel("Coups Echoués", 16, 360, 79, 17)
GUICtrlSetColor(-1, 0xFF0000)
$CoupsEchoues = GUICtrlCreateLabel("0", 95, 360, 20, 17)
GUICtrlCreateGroup("", -99, -99, 1, 1)
;=Groupe Etat=
$GroupEtat = GUICtrlCreateGroup("Etat", 120, 320, 129, 65)
$LabelEtat = GUICtrlCreateLabel("Jeu en cours", 128, 336, 112, 17)
GUICtrlCreateLabel("Niveau", 128, 360, 38, 17)
$Niveau = GUICtrlCreateLabel("Facile", 184, 360, 32, 17)
GUICtrlCreateGroup("", -99, -99, 1, 1)
;=Groupe Vitesse=
$GroupVitesse = GUICtrlCreateGroup("Vitesse", 248, 320, 137, 65)
GUICtrlCreateLabel("Vitesse de jeu", 256, 336, 70, 17)
$InfoVitesseJeu = GUICtrlCreateLabel("Modérée", 336, 336, 46, 17)
GUICtrlCreateLabel("Création lettres", 256, 360, 74, 17)
$InfoCreationLettre = GUICtrlCreateLabel("Modérée", 336, 360, 46, 17)
GUICtrlCreateGroup("", -99, -99, 1, 1)
;=Menu=
$MenubarFichier = GUICtrlCreateMenu("Fichier")
    $FilePause = GUICtrlCreateMenuItem("Pause (F1)", $MenubarFichier)
    $FileOptions = GUICtrlCreateMenuItem("Options (F11)", $MenubarFichier)
    $FileQuitter = GUICtrlCreateMenuItem("Quitter (F12)", $MenubarFichier)
;=Afficher=
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###


;=Création Lettres=
NewLettre()
AdLibRegister("NewLettre", $VitesseCreationLettres)
$Begin = TimerInit()


;===Boucle Principale===
While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            _Exit()

        ;=MenubarFichier=
        Case $FilePause
            _Pause()

        Case $FileOptions
            _Options()

        Case $FileQuitter
            _Exit()
    EndSwitch

    ;=Gestion de l'appuie sur touche=
    If _IsPressed("41") Then $Key = "a"
    If _IsPressed("42") Then $Key = "b"
    If _IsPressed("43") Then $Key = "c"
    If _IsPressed("44") Then $Key = "d"
    If _IsPressed("45") Then $Key = "e"
    If _IsPressed("46") Then $Key = "f"
    If _IsPressed("47") Then $Key = "g"
    If _IsPressed("48") Then $Key = "h"
    If _IsPressed("49") Then $Key = "i"
    If _IsPressed("4A") Then $Key = "j"
    If _IsPressed("4B") Then $Key = "k"
    If _IsPressed("4C") Then $Key = "l"
    If _IsPressed("4D") Then $Key = "m"
    If _IsPressed("4E") Then $Key = "n"
    If _IsPressed("4F") Then $Key = "o"
    If _IsPressed("50") Then $Key = "p"
    If _IsPressed("51") Then $Key = "q"
    If _IsPressed("52") Then $Key = "r"
    If _IsPressed("53") Then $Key = "s"
    If _IsPressed("54") Then $Key = "t"
    If _IsPressed("55") Then $Key = "u"
    If _IsPressed("56") Then $Key = "v"
    If _IsPressed("57") Then $Key = "w"
    If _IsPressed("58") Then $Key = "x"
    If _IsPressed("59") Then $Key = "y"
    If _IsPressed("5A") Then $Key = "z"

    ;=Gestion des coups réussis=
    If NOT StringInStr($String, $Key) Then
        For $i = 0 to UBound($Labels)-2
            If GuiCtrlRead($Labels[$i]) = $Key Then
                _Green()
                AdlibRegister("_Red", 1000)
                GuiCtrlDelete($Labels[$i])
                _ArrayDelete($Labels, $i)
                $String &= $Key
                $Reussis += 1
                GuiCtrlSetData($CoupsReussis, $Reussis)
            EndIf
        Next
    EndIf

    ;=Déplacement des lettres=
    If TimerDiff($Begin)>$VitesseDescente Then
        For $i = 0 to UBound($Labels)-2
            $Pos = ControlGetPos ($GUI, "", $Labels[$i])
            If $Pos[1]>236 Then
                GUICtrlSetBkColor($Labels[$i], 0xff9999)
            EndIf
            If $Pos[1]>256 Then
                GUICtrlSetBkColor($Labels[$i], 0xff2222)
            EndIf
            If $Pos[1]>280 Then
                $String &= GuiCtrlRead($Labels[$i])
                GUICtrlSetBkColor($Labels[$i], 0xff0000)
                GuiCtrlDelete($Labels[$i])
                _ArrayDelete($Labels, $i)
                $Echoues += 1
                GuiCtrlSetData($CoupsEchoues, $Echoues)
            Else
                GUICtrlSetPos($Labels[$i], $Pos[0], $Pos[1]+20)
            EndIf
        Next
        $Begin = TimerInit()
    EndIf
WEnd

Func _Green()
    GUICtrlSetBkColor($BarreBas, 0x00FF00)
    GUICtrlSetBkColor($BarreHaut, 0x00FF00)
    AdlibRegister("_Red", 1000)
EndFunc

Func _Red()
    GUICtrlSetColor($BarreBas, 0xFF0000)
    GUICtrlSetColor($BarreHaut, 0xFF0000)
    AdlibUnRegister("_Red")
EndFunc

;===Fonction NewLettre()
Func NewLettre()
    $Char = StringSplit($String, "")
    $Lettre = $Char[Random(1, $Char[0]-1, 1)]
    $xPos = Random(1, 18, 1)*20
    $New = GUICtrlCreateLabel ($Lettre, $xPos, 68, 20, 20, 1)
    GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT)
    _ArrayAdd($Labels, $New)
    $String = StringReplace($String, $Lettre, "")
EndFunc


;===Fonction HotKeys===
;===Fonction EXIT F12===
Func _Exit()
    Exit
EndFunc

;===Fonction PAUSE F1===
Func _Pause()
    ;==Pause Flood==
    If GUICtrlRead($LabelEtat) = "Jeu en cours" Then
        While 1
            Sleep(100)
            GUICtrlSetData($LabelEtat, "Jeu en pause")
        WEnd
    ElseIf GUICtrlRead($LabelEtat) = "Jeu en pause" Then
        GUICtrlSetData($LabelEtatFlood, "Jeu en cours")
        Sleep(100)
    EndIf
EndFunc

La partie de code correspondante se trouve à la ligne 122 (appel de la fonction _Green) et j'ai ajouté tes deux fonctions juste après ma main boucle.

Le problème est que maintenant les barres restent vertes même lorsque je ne rentre pas une touche correcte ou que je laisse passer les lettres.
Merci de ton aide.

[mikell]

je n'ai que fait de reprendre du travail de Mikell à ce sujet

Rôôô ben fallait le dire tout de suite, je t'aurais donné une solution à moi
Dans ce genre de script je gère ça avec un timer (je reprends mon script pour exemple, c'est plus simle) :

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Array.au3>
#include <Misc.au3>

Global $key, $win = -1, $lost = 0, [color=#FF0000]$t[/color]
Dim $labels[1]
Global $string = "azertyuiopqsdfghjklmwxcvbn"


;======REGLAGES============
Global $vitesse_creation_lettres = 1000
Global $vitesse_descente = 500
;===========================

$gui = GUICreate("My GUI", -1, -1, 400, 400)
GUISetBkColor(0xffffff)
GUISetFont(12, 600, 0, "Tahoma")
[color=#FF0000]$ligne = GUICtrlCreateLabel ("", 0, 330, 400, 4)[/color]
GUICtrlSetBkColor(-1, 0xff0000)
GUICtrlCreateLabel ("SCORE", 20, 340, 80, 20)
GUICtrlCreateLabel ("gagnés :", 120, 340, 70, 20)
$winlabel = GUICtrlCreateLabel ("", 200, 340, 30, 20)
GUICtrlCreateLabel ("perdus :", 260, 340, 70, 20)
$lostlabel = GUICtrlCreateLabel ("0", 340, 340, 30, 20)
GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT)
GUISetState()
 
New_Lettre()
AdLibRegister("New_Lettre", $vitesse_creation_lettres)
$begin = TimerInit()


While 1

If _IsPressed("41") Then $key = "a"
If _IsPressed("42") Then $key = "b"
If _IsPressed("43") Then $key = "c"
If _IsPressed("44") Then $key = "d"
If _IsPressed("45") Then $key = "e"
If _IsPressed("46") Then $key = "f"
If _IsPressed("47") Then $key = "g"
If _IsPressed("48") Then $key = "h"
If _IsPressed("49") Then $key = "i"
If _IsPressed("4A") Then $key = "j"
If _IsPressed("4B") Then $key = "k"
If _IsPressed("4C") Then $key = "l"
If _IsPressed("4D") Then $key = "m"
If _IsPressed("4E") Then $key = "n"
If _IsPressed("4F") Then $key = "o"
If _IsPressed("50") Then $key = "p"
If _IsPressed("51") Then $key = "q"
If _IsPressed("52") Then $key = "r"
If _IsPressed("53") Then $key = "s"
If _IsPressed("54") Then $key = "t"
If _IsPressed("55") Then $key = "u"
If _IsPressed("56") Then $key = "v"
If _IsPressed("57") Then $key = "w"
If _IsPressed("58") Then $key = "x"
If _IsPressed("59") Then $key = "y"
If _IsPressed("5A") Then $key = "z"

If NOT StringInStr($string, $key) Then
    For $i = 0 to UBound($labels)-2
        If GuiCtrlRead($labels[$i]) = $key Then
            GuiCtrlDelete($labels[$i])
            _ArrayDelete($labels, $i)
            $string &= $key
            $win += 1  
            GuiCtrlSetData($winlabel, $win)
[color=#FF0000]            If $win>0 Then 
               $t = TimerInit()
               GUICtrlSetBkColor($ligne, 0x00FF00)
            EndIf[/color]
        EndIf
    Next
EndIf
[color=#FF0000]If TimerDiff($t)>500 Then GUICtrlSetBkColor($ligne, 0xFF0000)[/color]

If TimerDiff($begin)>$vitesse_descente Then
    For $i = 0 to UBound($labels)-2
        $pos = ControlGetPos ($gui, "", $labels[$i])
        If $pos[1]>260 Then
            GUICtrlSetBkColor($labels[$i], 0xff9999)
        EndIf
        If $pos[1]>280 Then
            GUICtrlSetBkColor($labels[$i], 0xff2222)
        EndIf
        If $pos[1]>290 Then
            $string &= GuiCtrlRead($labels[$i])
            GUICtrlSetBkColor($labels[$i], 0xff0000)
            GuiCtrlDelete($labels[$i])
            _ArrayDelete($labels, $i)
            $lost += 1  
            GuiCtrlSetData($lostlabel, $lost)
        Else
            GUICtrlSetPos($labels[$i], $pos[0], $pos[1]+20)
        EndIf
    Next
    $begin = TimerInit()
EndIf

$msg = GUIGetMsg()
If $msg = $GUI_EVENT_CLOSE Then ExitLoop

WEnd


Func New_Lettre()
$char = StringSplit($string, "")
$lettre = $char[Random(1, $char[0]-1, 1)]
$xpos = Random(1, 18, 1)*20
$new = GUICtrlCreateLabel ($lettre, $xpos, 10, 20, 20, 1)   ; $SS_CENTER = 0x1
GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT)
_ArrayAdd($labels, $new)
$string = StringReplace($string, $lettre, "")
EndFunc
 

[Kagami]

C'est parfait, c'était ce qu'il me fallait, merci =)