UDF > WinAPIEx > ShellEx >

_WinAPI_ShellSetLocalizedName

Définit le nom localisé d'un fichier d'un dossier Shell

#include <WinAPIShellEx.au3>
_WinAPI_ShellSetLocalizedName ( $sFilePath, $sModule, $iResID )

Paramètres

$sFilePath Le chemin d'accès au fichier cible.
$sModule Le chemin vers le module contenant la ressource chaîne qui spécifie la version localisée du nom de fichier.
$iResID ID de la ressource de nom de fichier localisé.

Valeur de retour

Succès: Retourne 1.
Échec: Retourne 0 et définit @error <> 0, @extended peut contenir le code d'erreur HRESULT.

Remarques

Lorsque cette chaîne est définie, l'Explorateur Windows affiche cette chaîne à la place du nom de fichier. Le chemin d'accès au fichier est inchangé.

Cette fonction nécessite Windows Vista ou une version ultérieure.

Voir aussi

Consultez SHSetLocalizedName dans la librairie MSDN.

Exemple

#include <MsgBoxConstants.au3>
#include <WinAPIShellEx.au3>
#include <WinAPIShPath.au3>
#include <WinAPISys.au3>

If Number(_WinAPI_GetVersion()) < 6.0 Then
    MsgBox(BitOR($MB_ICONERROR, $MB_SYSTEMMODAL), 'Erreur', 'Nécessite Windows Vista ou une version ultérieure.')
    Exit
EndIf

Local Const $sDll = @ScriptDir & '\Extras\Resources.dll'
Local Const $sDir = @TempDir & '\Temporary Folder'

If Not FileExists($sDll) Then
    MsgBox(BitOR($MB_ICONERROR, $MB_SYSTEMMODAL), 'Erreur', $sDll & ' non trouvé.')
    Exit
EndIf

If Not DirCreate($sDir) Then
    MsgBox(BitOR($MB_ICONERROR, $MB_SYSTEMMODAL), 'Erreur', 'Impossible de créer le dossier.')
    Exit
EndIf

_WinAPI_ShellOpenFolderAndSelectItems($sDir)
MsgBox(BitOR($MB_ICONINFORMATION, $MB_SYSTEMMODAL), '', 'Pressez OK pour définir le nom localisé de "' & _WinAPI_PathStripPath($sDir) & '".')
_WinAPI_ShellSetLocalizedName($sDir, $sDll, 6000)
MsgBox(BitOR($MB_ICONINFORMATION, $MB_SYSTEMMODAL), '', 'Pressez OK pour supprimer le nom localisé.')
_WinAPI_ShellRemoveLocalizedName($sDir)
MsgBox(BitOR($MB_ICONINFORMATION, $MB_SYSTEMMODAL), '', 'Pressez OK pour terminer le script.')

DirRemove($sDir, 1)