Functions > FileDirDisk >

DirRemove

Supprime un répertoire.

DirRemove ( "path" [, recurse = 0] )

Paramètres

path Chemin du répertoire à supprimer.
recurse [optionnel] Utilisez ce flag pour spécifier si vous voulez également supprimer les sous-répertoires.
    $DIR_DEFAULT (0) = (par défaut) supprime le répertoire seulement s'il est vide
    $DIR_REMOVE (1) = supprime les fichiers et sous-répertoires (comme la commande DOS Deltree)

Les constantes sont définies dans "AutoItConstants.au3".

Valeur de retour

Succès: Retourne 1.
Échec: Retourne 0 s'il y a eu une erreur de suppression du répertoire (ou si le répertoire n'existe pas).

Remarque

Certains attributs du dossier peuvent rendre la suppression impossible, cependant si c'est le cas, consultez FileSetAttrib() pour changer les attributs d'un répertoire.

En relation

DirCopy, DirCreate, DirMove, FileDelete, FileRecycle

Exemple

#include <AutoItConstants.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    ; Crée une constante de portée Local avec le répertoire.
    Local Const $sFilePath = @TempDir & "\DirCreateFolder"

    ; Si le répertoire existe ne continue pas.
    If FileExists($sFilePath) Then
        MsgBox($MB_SYSTEMMODAL, "", "Une erreur est survenue. Le répertoire existe déjà.")
        Return False
    EndIf

    ; Ouvre le répertoire Temp.
    ShellExecute(@TempDir)

    ; Crée le répertoire.
    DirCreate($sFilePath)

    ; Affiche un message sur la création du répertoire.
    MsgBox($MB_SYSTEMMODAL, "", "Le répertoire a été créé.")

    ; Supprime le répertoire et tous ses sous-répertoires.
    DirRemove($sFilePath, $DIR_REMOVE)

    ; Affiche un message sur la suppression.
    MsgBox($MB_SYSTEMMODAL, "", "Le sous répertoire: Folder2 a été supprimé.")
EndFunc   ;==>Example