UDF > WinAPIEx > ShellEx >

_WinAPI_SetCurrentProcessExplicitAppUserModelID

Spécifie un unique Application User Model Id défini par l'application qui identifie le processus actuel de la barre des tâches

#include <WinAPIShellEx.au3>
_WinAPI_SetCurrentProcessExplicitAppUserModelID ( $sAppID )

Paramètres

$sAppID La chaîne qui représente un Application User Model Id (AppUserModelID). Cet identifiant permet à une application de regrouper ses processus et ses fenêtres associées sous un seul bouton de la barre des tâches. Une application doit fournir son AppUserModelID dans le format ci-dessous, ne peut pas avoir plus de 128 caractères et ne peut pas contenir d'espace.

CompanyName.ProductName.SubProduct.VersionInformation
(Voir MSDN pour plus d'informations)

Valeur de retour

Succès: Retourne 1.
Échec: Retourne 0 et définit @error <> 0, @extended peut contenir le code d'erreur HRESULT.

Remarques

Cette fonction doit être appelée lors de la première routine de démarrage d'une application avant que l'application présente une interface utilisateur ou fasse une manipulation de ses Jump Lists.

Cette fonction nécessite Windows 7 ou une version ultérieure.

Voir aussi

Consultez SetCurrentProcessExplicitAppUserModelID dans la librairie MSDN.

Exemple

#NoTrayIcon

#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>
#include <WinAPIShellEx.au3>
#include <WinAPISys.au3>

If Number(_WinAPI_GetVersion()) < 6.1 Then
    MsgBox(BitOR($MB_ICONERROR, $MB_SYSTEMMODAL), 'Erreur', 'Necessite Windows 7 ou une version ultérieure.')
    Exit
EndIf

Local $sAppID = 'Yashied.WinAPIEx.UDF'

Local $sParam
If Not $CmdLine[0] Then
    For $i = 1 To 5
        Switch $i
            Case 1 To 2
                $sParam = $sAppID & '.' & $i
            Case Else
                $sParam = $sAppID & '.3'
        EndSwitch
        If Not @Compiled Then
            Run(@AutoItExe & '"' & @ScriptFullPath & '" ' & $sParam)
        Else
            Run(@AutoItExe & '' & $sParam)
        EndIf
        Sleep(100)
    Next
    Exit
EndIf

_WinAPI_SetCurrentProcessExplicitAppUserModelID($CmdLine[1])

GUICreate($CmdLine[1], 400, 400)
GUISetState(@SW_SHOWMINIMIZED)

Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE