UDF > WinAPIEx > Processes & Synchronization > Synchronization >

_WinAPI_ResetEvent

Définit l'objet d'événement spécifié à l'état non signalé

#include <WinAPIProc.au3>
_WinAPI_ResetEvent ( $hEvent )

Paramètre

$hEvent Handle de l'objet d'événement. La fonction _WinAPI_CreateEvent() retourne ce handle.

Valeur de retour

Succès: Retourne True.
Échec: Retourne False, appelez _WinAPI_GetLastError() pour obtenir des informations supplémentaires sur l'erreur.

Remarques

L'état d'un objet événement reste non signalé jusqu'à ce qu'il soit explicitement définie à signalé par la fonction _WinAPI_SetEvent(). Cet état non signalé bloque l'exécution des threads qui ont spécifié l'objet d'événement en appelant une des fonctions _WinAPI_Wait....

La fonction _WinAPI_ResetEvent() est utilisée principalement pour les objets d'événement de réinitialisation manuelle, qui doivent être définies explicitement à l'état non signalé.
Les objets d'événement de réinitialisation automatique changent automatiquement de signalé à non signalé après qu'un seul thread en attente soit libéré.

En relation

_WinAPI_CreateEvent, _WinAPI_SetEvent

Voir aussi

Consultez ResetEvent dans la librairie MSDN.

Example

#include <WinAPIHObj.au3>
#include <WinAPIProc.au3>

Global $g_tEvents = DllStructCreate("handle Event[3];")
$g_tEvents.Event(1) = _WinAPI_CreateEvent(0, True, False)
$g_tEvents.Event(2) = _WinAPI_CreateEvent(0, True, False)
$g_tEvents.Event(3) = _WinAPI_CreateEvent(0, True, False)

HotKeySet("{ESC}", "_Exit")
AdlibRegister("_FireEvent_1", 500)
AdlibRegister("_FireEvent_2", 800)

Local $iEvent
Do
    $iEvent = _WinAPI_WaitForMultipleObjects(3, $g_tEvents, False, 100)
    Switch $iEvent
        Case 0
            ConsoleWrite("+ First Event" & @CRLF)
            _WinAPI_ResetEvent($g_tEvents.Event(1))
        Case 1
            ConsoleWrite("> Second Event" & @CRLF)
            _WinAPI_ResetEvent($g_tEvents.Event(2))
    EndSwitch
Until $iEvent = 2 Or $iEvent = -1 ;Erreur

If $iEvent = 2 Then 
    ConsoleWrite("! Exit Event" & @CRLF)
    AdlibUnRegister("_FireEvent_1")
    AdlibUnRegister("_FireEvent_2")
    _WinAPI_CloseHandle($g_tEvents.Event(1))
    _WinAPI_CloseHandle($g_tEvents.Event(2))
    _WinAPI_CloseHandle($g_tEvents.Event(3))
EndIf

Func _Exit()
    _WinAPI_SetEvent($g_tEvents.Event(3))
EndFunc   ;==>_Exit

Func _FireEvent_1()
    _WinAPI_SetEvent($g_tEvents.Event(1))
EndFunc   ;==>_FireEvent_1

Func _FireEvent_2()
    _WinAPI_SetEvent($g_tEvents.Event(2))
EndFunc   ;==>_FireEvent_2