UDF > WinAPIEx > Files & Devices > Files >

_WinAPI_GetVolumeNameForVolumeMountPoint

Obtient le chemin GUID d'un volume qui est associé au point de montage spécifié

#include <WinAPIFiles.au3>
_WinAPI_GetVolumeNameForVolumeMountPoint ( $sMountedPath )

Paramètre

$sMountedPath Le chemin d'un répertoire monté (par exemple, Y:\MountX\) ou une lettre de lecteur (par exemple, X:\).

Valeur de retour

Succès: Retourne le chemin GUID du volume. Ce chemin est de la forme "\\?\Volume{GUID}" où GUID est un GUID qui identifie le volume. S'il y a plus d'un chemin GUID de volume pour le volume, seul le premier dans la mémoire cache du gestionnaire de montage est retourné.
Échec: Définit @error <> 0, appelez _WinAPI_GetLastError() pour obtenir des informations sur l'erreur.

Voir aussi

Consultez GetVolumeNameForVolumeMountPoint dans la librairie MSDN.

Exemple

#include <MsgBoxConstants.au3>
#include <WinAPIFiles.au3>

Local $sPath = @TempDir & '\Mount'
Local $iCount = 0

While FileExists($sPath & $iCount)
    $iCount += 1
WEnd

$sPath &= $iCount & '\'

If Not DirCreate($sPath) Then
    MsgBox(BitOR($MB_ICONERROR, $MB_SYSTEMMODAL), 'Erreur', 'Impossible de créer le répertoire.')
    Exit
EndIf

Local $sGUID = _WinAPI_GetVolumeNameForVolumeMountPoint(@HomeDrive & '\')
If _WinAPI_SetVolumeMountPoint($sPath, $sGUID) Then
    MsgBox(BitOR($MB_ICONINFORMATION, $MB_SYSTEMMODAL), '', 'Le lecteur "' & StringUpper(@HomeDrive) & '" a été associé à "'& $sPath & '".' & @CRLF & @CRLF & 'Pressez OK pour supprimer l''association.')
    _WinAPI_DeleteVolumeMountPoint($sPath)
Else
    MsgBox(BitOR($MB_ICONERROR, $MB_SYSTEMMODAL), 'Erreur', 'Impossible de monter le répertoire.')
EndIf

DirRemove($sPath)