UDF > GUI > GuiTreeView >

_GUICtrlTreeView_SetScrollTime

Définit le temps de défilement maximal

#include <GuiTreeView.au3>
_GUICtrlTreeView_SetScrollTime ( $hWnd, $iTime )

Paramètres

$hWnd ID/handle du contrôle
$iTime Nouveau temps maximal de défilement, en millisecondes

Valeur de retour

Retourne le temps de défilement précédent, en millisecondes.

Remarque

Le temps de défilement maximal est le temps le plus long qu'une opération de défilement peut prendre.
Le défilement sera ajustée de sorte que le noeud prendra sa place dans le délai de défilement maximal.
Une opération de défilement peut prendre moins de temps que le maximum.

En relation

_GUICtrlTreeView_GetScrollTime

Exemple

#include <GUIConstantsEx.au3>
#include <GuiTreeView.au3>
#include <MsgBoxConstants.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $aidItem[10], $idTreeView
    Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)

    GUICreate("(Internal) TreeView Set Scroll Time", 400, 300)

    $idTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
    GUISetState(@SW_SHOW)

    _GUICtrlTreeView_BeginUpdate($idTreeView)
    For $x = 0 To 9
        $aidItem[$x] = GUICtrlCreateTreeViewItem(StringFormat("[%02d] New Item", $x), $idTreeView)
        For $y = 1 To Random(2, 10, 1)
            GUICtrlCreateTreeViewItem(StringFormat("[%02d] New Child", $y), $aidItem[$x])
        Next
    Next
    _GUICtrlTreeView_EndUpdate($idTreeView)

    MsgBox($MB_SYSTEMMODAL, "Information", "Scroll Time: " & _GUICtrlTreeView_GetScrollTime($idTreeView) & " milliseconds")
    _GUICtrlTreeView_SetScrollTime($idTreeView, 2)
    MsgBox($MB_SYSTEMMODAL, "Information", "Scroll Time: " & _GUICtrlTreeView_GetScrollTime($idTreeView) & " milliseconds")

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example