UDF > GUI > GuiTreeView >


_GUICtrlTreeView_GetVisibleCount

Retourne le nombre de noeuds qui peuvent être entièrement visible dans la vue du contrôle

#include <GuiTreeView.au3>
_GUICtrlTreeView_GetVisibleCount ( $hWnd )

Paramètre

$hWnd ID/handle du contrôle

Valeur de retour

Retourne le nombre maximum de noeuds éventuellement visibles dans le contrôle.

Remarque

Le nombre de noeuds qui peuvent être entièrement visible peut être supérieur au nombre de noeuds du contrôle.
La contrôle calcule cette valeur en divisant la hauteur de la fenêtre client par la hauteur d'un noeud.
Notez que la valeur de retour est le nombre de noeuds qui peuvent être entièrement visible.
Si vous pouvez voir l'ensemble des 20 noeuds et une partie d'un noeud en plus, la valeur de retour est de 20 pas 21.

Exemple

#include <GUIConstantsEx.au3>
#include <GuiTreeView.au3>
#include <MsgBoxConstants.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $idTreeView
    Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS)

    GUICreate("TreeView Get Visible Count", 400, 300)

    $idTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
    GUISetState(@SW_SHOW)

    _GUICtrlTreeView_BeginUpdate($idTreeView)
    For $x = 0 To 99
        _GUICtrlTreeView_Add($idTreeView, 0, StringFormat("[%02d] New Item", $x))
    Next
    _GUICtrlTreeView_EndUpdate($idTreeView)

    MsgBox($MB_SYSTEMMODAL, "Information", "Visible: " & _GUICtrlTreeView_GetVisibleCount($idTreeView))

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example