UDF > GUI > GuiTreeView >

_GUICtrlTreeView_ExpandedOnce

Indique si la liste des noeuds enfants a été développée au moins une fois

#include <GuiTreeView.au3>
_GUICtrlTreeView_ExpandedOnce ( $hWnd, $hItem )

Paramètres

$hWnd ID/handle du contrôle
$hItem Handle du noeud

Valeur de retour

Retourne True: le noeud a été développé au moins une fois.
Retourne False: le noeud n'a pas été développé au moins une fois.

En relation

_GUICtrlTreeView_Expand

Exemple

#include <GUIConstantsEx.au3>
#include <GuiTreeView.au3>
#include <MsgBoxConstants.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $aidItem[5], $idTreeView
    Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)

    GUICreate("TreeView Expanded Once", 400, 300)

    $idTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
    GUISetState(@SW_SHOW)

    _GUICtrlTreeView_BeginUpdate($idTreeView)
    For $x = 0 To 4
        $aidItem[$x] = GUICtrlCreateTreeViewItem(StringFormat("[%02d] New Item", $x), $idTreeView)
        For $y = 0 To 2
            GUICtrlCreateTreeViewItem(StringFormat("[%02d] New Item", $y), $aidItem[$x])
        Next
    Next
    _GUICtrlTreeView_EndUpdate($idTreeView)

    MsgBox($MB_SYSTEMMODAL, "Information", "Expand item 0")
    _GUICtrlTreeView_Expand($idTreeView, $aidItem[0])

    MsgBox($MB_SYSTEMMODAL, "Information", "Collapse item 0")
    _GUICtrlTreeView_Expand($idTreeView, $aidItem[0], False)

    MsgBox($MB_SYSTEMMODAL, "Information", "Item 0 expanded at least once? " & _GUICtrlTreeView_ExpandedOnce($idTreeView, $aidItem[0]))
    MsgBox($MB_SYSTEMMODAL, "Information", "Item 1 expanded at least once? " & _GUICtrlTreeView_ExpandedOnce($idTreeView, $aidItem[1]))

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example