UDF > GUI > GuiTreeView >

_GUICtrlTreeView_AddFirst

Ajoute un nouveau noeud au début de la liste des frères

#include <GuiTreeView.au3>
_GUICtrlTreeView_AddFirst ( $hWnd, $hSibling, $sText [, $iImage = -1 [, $iSelImage = -1]] )

Paramètres

$hWnd ID/handle du contrôle
$hSibling Noeud de la fratrie
$sText Texte associé au noeud
$iImage [optionnel] Index, à partir de 0, de l'icône du noeud, dans la liste des images du contrôle
$iSelImage [optionnel] Index, à partir de 0, de l'icône du noeud, dans la liste des images du contrôle

Valeur de retour

Succès: Retourne le handle du nouveau noeud.
Échec: Retourne 0.

Remarque

Le noeud est ajouté en tant que premier frère de $hSibling. Les noeuds qui apparaissent après le noeud ajouté sont déplacés vers le bas.

En relation

_GUICtrlTreeView_Add

Exemple

#include <GUIConstantsEx.au3>
#include <GuiTreeView.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $hItem, $idTreeView
    Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)

    GUICreate("TreeView Add First", 400, 300)

    $idTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
    GUISetState(@SW_SHOW)

    _GUICtrlTreeView_BeginUpdate($idTreeView)
    For $x = 1 To Random(2, 10, 1)
        $hItem = _GUICtrlTreeView_Add($idTreeView, 0, StringFormat("[%02d] New Item", $x))
        For $y = 1 To Random(2, 10, 1)
            _GUICtrlTreeView_AddChild($idTreeView, $hItem, StringFormat("[%02d] New Child", $y))
        Next
    Next
    _GUICtrlTreeView_AddFirst($idTreeView, $hItem, "[00] New First Item")
    _GUICtrlTreeView_EndUpdate($idTreeView)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example