UDF > GUI > GuiMonthCal >

_GUICtrlMonthCal_SetDayState

Définit les jours en gras pour tous les mois qui sont actuellement visibles

#include <GuiMonthCal.au3>
_GUICtrlMonthCal_SetDayState ( $hWnd, $aMasks )

Paramètres

$hWnd ID ou handle du contrôle Month Calendar
$aMasks Un tableau d'entiers qui correspond aux mois qui sont visibles dans le calendrier

Valeur de retour

Succès: Retourne True.
Échec: Retourne False.

Remarque

Vous devez créer le contrôle de calendrier avec le style $MCS_DAYSTATE si vous souhaitez utiliser cette fonction.

Exemple

#include <GUIConstantsEx.au3>
#include <GuiMonthCal.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $idMonthCal

    ; Crée une GUI
    GUICreate("Month Calendar Set Day State", 400, 300)
    $idMonthCal = GUICtrlCreateMonthCal("", 4, 4, -1, -1, BitOR($WS_BORDER, $MCS_DAYSTATE), 0x00000000)

    ; Obtient le nombre de mois sur lesquels nous devons fournir des masques. Normalement, ce nombre est 3.
    Local $aMasks[_GUICtrlMonthCal_GetMonthRangeSpan($idMonthCal, True)]

    ; Met en gras le 1er, le 8 et le 16 du mois en cours. Cela se traduit par un masque binaire de 1000 0000 1000 0001 ou
    ; 0x8081 en hexadécimal.
    ; La n-ième position binaire à partir de la droite concerne le n-ième jour du mois; chaque groupe de 4 chiffres binaires
    ; définit un chiffre hexadécimal. Il y donc 8 chiffres hexadécimaux au maximum.
    $aMasks[1] = 0x8081
    _GUICtrlMonthCal_SetDayState($idMonthCal, $aMasks)

    GUISetState(@SW_SHOW)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example