UDF > GUI > GuiMenu >


_GUICtrlMenu_CreatePopup

Crée un menu déroulant, un sous-menu ou un raccourci

#include <GuiMenu.au3>
_GUICtrlMenu_CreatePopup ( [$iStyle = $MNS_CHECKORBMP] )

Paramètre

$iStyle [optionnel] Style du menu. Peut prendre une ou plusieurs des valeurs suivantes :
$MNS_AUTODISMISS - La menu se ferme automatiquement lorsque la souris reste en dehors du menu pendant 10 secondes
$MNS_CHECKORBMP - Le même espace est réservé pour la case à cocher et le bitmap (valeur par défaut)
$MNS_DRAGDROP - Les éléments du menu sont cibles d'un Drop OLE ou sources d'un Drag
$MNS_MODELESS - Le menu est une boîte modale
$MNS_NOCHECK - Pas d'espace est réservé à gauche d'un élément pour une case à cocher
$MNS_NOTIFYBYPOS - Le propriétaire du menu reçoit un message WM_MENUCOMMAND à la place d'un message WM_COMMAND pour les sélections

Valeur de retour

Succès: Retourne le handle du menu créé.
Échec: Retourne 0.

Remarque

Les ressources de menu qui sont affectés à une fenêtre sont libérés automatiquement. Si le menu n'est pas affecté à une fenêtre, une application doit libérer les ressources système associées au menu avant la fermeture.
Une application libère les ressources d'un menu en appelant la fonction _GUICtrlMenu_DestroyMenu().
$MNS_NOTIFYBYPOS est un style d'en-tête de menu et n'a aucun effet lorsqu'elle est appliquée à des sous-menus

En relation

_GUICtrlMenu_CreateMenu, _GUICtrlMenu_DestroyMenu

Voir aussi

Consultez CreatePopupMenu dans la librarie MSDN.

Exemple

#include <GUIConstantsEx.au3>
#include <GuiMenu.au3>
#include <WinAPIError.au3>
#include <WindowsConstants.au3>

Global Enum $e_idOpen = 1000, $e_idSave, $e_idInfo

Example()

Func Example()
    ; Crée une GUI
    GUICreate("Menu", 400, 300)
    GUISetState(@SW_SHOW)

    ; Crée un gestionnaire de messages
    GUIRegisterMsg($WM_COMMAND, "WM_COMMAND")
    GUIRegisterMsg($WM_CONTEXTMENU, "WM_CONTEXTMENU")

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Répond aux messages WM_COMMAND
Func WM_COMMAND($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg, $lParam
    Switch $wParam
        Case $e_idOpen
            _WinAPI_ShowMsg("Open")
        Case $e_idSave
            _WinAPI_ShowMsg("Save")
        Case $e_idInfo
            _WinAPI_ShowMsg("Info")
    EndSwitch
EndFunc   ;==>WM_COMMAND

; Gére les messages WM_CONTEXTMENU
Func WM_CONTEXTMENU($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg, $lParam
    Local $hMenu

    $hMenu = _GUICtrlMenu_CreatePopup()
    _GUICtrlMenu_InsertMenuItem($hMenu, 0, "Open", $e_idOpen)
    _GUICtrlMenu_InsertMenuItem($hMenu, 1, "Save", $e_idSave)
    _GUICtrlMenu_InsertMenuItem($hMenu, 3, "", 0)
    _GUICtrlMenu_InsertMenuItem($hMenu, 3, "Info", $e_idInfo)
    _GUICtrlMenu_TrackPopupMenu($hMenu, $wParam)
    _GUICtrlMenu_DestroyMenu($hMenu)
    Return True
EndFunc   ;==>WM_CONTEXTMENU