UDF > GUI > GuiMenu >

_GUICtrlMenu_AppendMenu

Ajoute un nouvel élément à la fin d'une barre de menu, dans un menu déroulant, un sous-menu ou un raccourci spécifié

#include <GuiMenu.au3>
_GUICtrlMenu_AppendMenu ( $hMenu, $iFlags, $iNewItem, $vNewItem )

Paramètres

$hMenu Handle du contrôle Menu
$iFlags Définit les indicateurs qui contrôlent l'apparence et le comportement du nouveau élément de menu:
    $MF_BITMAP - Utilise un bitmap comme élément de menu
    $MF_CHECKED - Place une case cochée à côté de l'élément de menu. Si l'application fournit des bitmaps pour les cases cochées, cet indicateur affiche le bitmap à côté de l'élément de menu.
    $MF_DISABLED - Désactive l'élément de menu afin qu'il ne puisse pas être sélectionné, mais ne le grise pas.
    $MF_ENABLED - Active l'élément de menu de sorte qu'il puisse être sélectionné, et le rétablit de son état grisé.
    $MF_GRAYED - Désactive l'élément de menu et le grise pour qu'il ne puisse pas être sélectionné.
    $MF_MENUBARBREAK - Fonctionne comme $MF_MENUBREAK pour une barre de menu. Pour un menu déroulant, un sous-menu, un raccourci, la nouvelle colonne est séparée de l'ancienne colonne par une ligne verticale.
    $MF_MENUBREAK - Place l'élément sur une nouvelle ligne (pour une barre de menu) ou dans une nouvelle colonne (pour un menu déroulant, un sous-menu ou un raccourci) sans colonnes de séparation.
    $MF_OWNERDRAW - Indique que l'élément gère lui-même sa peinture.
        Avant que le menu soit affiché la première fois, la fenêtre qui détient le menu reçoit un message $WM_MEASUREITEM pour récupérer la largeur et la hauteur de l'élément de menu.
        Le message $WM_DRAWITEM est ensuite envoyé à la fenêtre propriétaire chaque fois que l'apparence de l'élément de menu doit être mis à jour.
    MF_POPUP - Indique que l'élément de menu ouvre un menu déroulant ou un sous-menu.
        Le paramètre $iNewItem spécifie un handle de menu déroulant ou d'un sous-menu.
        Cet indicateur est utilisé pour ajouter un nom de menu à une barre de menu ou un élément de menu qui ouvre un sous-menu à dérouler, sous-menu ou un raccourci.
    $MF_SEPARATOR - Dessine une ligne de séparation horizontale. Cet indicateur est utilisé uniquement dans un menu déroulant, un sous-menu ou un raccourci.
        La ligne ne peut pas être grisée, désactivée ou mise en surbrillance. Les paramètres $vNewitem et $iNewitem sont ignorés.
    $MF_STRING - Indique que l'élément de menu est une chaîne de texte. Le paramètre $vNewitem est une chaîne.
    $MF_UNCHECKED - Ne place pas une case cochée à côté de l'élément. Si l'application fournit des bitmaps pour les cases cochées, cet indicateur affichera l'image bitmap décoché à côté de l'élément de menu.
$iNewitem Indique l'identifiant du nouvel élément de menu ou, si le paramètre $iFlags est défini à $MF_POPUP, le handle du menu déroulant ou du sous-menu.
$vNewitem Indique le contenu du nouvel élément de menu. L'interprétation de $vNewItem dépend du paramètre $iFlags qui peut inclure ou pas les indicateurs $MF_BITMAP, $MF_OWNERDRAW, et $MF_STRING:
    $MF_BITMAP - Contient le handle du bitmap
    $MF_OWNERDRAW - Contient une valeur fournie par l'application qui peut être utilisé pour conserver des données supplémentaires relatives à l'élément de menu.
    La valeur est dans le membre ItemData de la structure pointée par le paramètre lParam du message envoyé $WM_MEASUREitem ou $WM_DRAWitem lorsque le menu est créé ou que son apparence est mise à jour.
    $MF_STRING - Contient une chaîne

Valeur de retour

Succès: Retourne True.
Échec: Retourne False.

En relation

_GUICtrlMenu_InsertMenuItem

Voir aussi

Consultez AppendMenu dans la librairie MSDN.

Exemple

#include <GUIConstantsEx.au3>
#include <GuiMenu.au3>

Example()

Func Example()
    Local $hGUI, $hFile, $hEdit, $hHelp, $hMain
    Local Enum $e_idNew = 1000, $e_idOpen, $e_idSave, $e_idExit, $e_idCut, $e_idCopy, $e_idPaste, $e_idAbout

    ; Crée une GUI
    $hGUI = GUICreate("Menu", 400, 300)

    ; Crée un menu File
    $hFile = _GUICtrlMenu_CreateMenu()
    _GUICtrlMenu_InsertMenuItem($hFile, 0, "&New", $e_idNew)
    _GUICtrlMenu_InsertMenuItem($hFile, 1, "&Open", $e_idOpen)
    _GUICtrlMenu_InsertMenuItem($hFile, 2, "&Save", $e_idSave)
    _GUICtrlMenu_InsertMenuItem($hFile, 3, "", 0)
    _GUICtrlMenu_InsertMenuItem($hFile, 4, "E&xit", $e_idExit)

    ; Crée un menu Edit
    $hEdit = _GUICtrlMenu_CreateMenu()
    _GUICtrlMenu_InsertMenuItem($hEdit, 0, "&Cut", $e_idCut)
    _GUICtrlMenu_InsertMenuItem($hEdit, 1, "C&opy", $e_idCopy)
    _GUICtrlMenu_InsertMenuItem($hEdit, 2, "&Paste", $e_idPaste)

    ; Crée un menu Help
    $hHelp = _GUICtrlMenu_CreateMenu()

    ; Crée un menu Main
    $hMain = _GUICtrlMenu_CreateMenu()
    _GUICtrlMenu_InsertMenuItem($hMain, 0, "&File", 0, $hFile)
    _GUICtrlMenu_InsertMenuItem($hMain, 1, "&Edit", 0, $hEdit)
    _GUICtrlMenu_InsertMenuItem($hMain, 2, "&Help", 0, $hHelp)

    ; Attache le menu à la fenêtre
    _GUICtrlMenu_SetMenu($hGUI, $hMain)
    GUISetState(@SW_SHOW)

    ; Ajoute l'élément de menu About
    _GUICtrlMenu_AppendMenu($hHelp, $MF_STRING, $e_idAbout, "&About")

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example