UDF > GUI > GuiComboBoxEx >

_GUICtrlComboBoxEx_InsertString

Insère un nouvel élément dans le contrôle

#include <GuiComboBoxEx.au3>
_GUICtrlComboBoxEx_InsertString ( $hWnd, $sText [, $iIndex = -1 [, $iImage = -1 [, $iSelectedImage = -1 [, $iOverlayImage = -1 [, $iIndent = -1 [, $iParam = -1]]]]]] )

Paramètres

$hWnd Handle du contôle
$sText Texte de l'élément. S'il est défini à -1, l'élément est défini par l'intermédiaire du message de notification $CBEN_GETDISPINFO.
$iIndex [optionnel] Index, compté à partir de 0, auquel la nouvelle chaîne doit être insérée.
Pour insérer un élément à la fin de la liste, définissez $iIndex à -1
$iImage [optionnel] Index, compté à partir de 0, de l'icône de l'élément dans la liste d'images du contrôle
$iSelectedImage [optionnel] Index, compté à partir de 0, de l'icône de l'élément dans la liste d'images du contrôle
$iOverlayImage [optionnel] Index, compté à partir de 0, de l'icône de l'élément dans la liste d'images du contrôle
$iIndent [optionnel] Nombre de largeurs d'image du retrait de l'élément. Une seule indentation est égale à la largeur d'une image.
$iParam [optionnel] Valeur spécifique de l'élément

Valeur de retour

Succès: Retourne l'index du nouvel élément.
Échec: Retourne -1.

En relation

_GUICtrlComboBoxEx_InitStorage

Exemple

#include <GuiComboBoxEx.au3>
#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $hGUI, $hCombo

    ; Crée une GUI
    $hGUI = GUICreate("ComboBoxEx Insert String", 400, 300)
    $hCombo = _GUICtrlComboBoxEx_Create($hGUI, "", 2, 2, 394, 100)
    GUISetState(@SW_SHOW)

    ; Ajoute des fichiers
    _GUICtrlComboBoxEx_BeginUpdate($hCombo)
    _GUICtrlComboBoxEx_AddDir($hCombo, "", $DDL_DRIVES, False)
    _GUICtrlComboBoxEx_AddDir($hCombo, "", $DDL_DRIVES)
    _GUICtrlComboBoxEx_BeginUpdate($hCombo)
    _GUICtrlComboBoxEx_AddDir($hCombo, @WindowsDir & "\*.exe")
    _GUICtrlComboBoxEx_EndUpdate($hCombo)
    _GUICtrlComboBoxEx_EndUpdate($hCombo)

    ; Insère une chaîne
    _GUICtrlComboBoxEx_InsertString($hCombo, "Text inserted", 1)

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example