UDF > GUI > GuiComboBoxEx >

_GUICtrlComboBoxEx_GetComboBoxInfo

Obtient des informations sur le contrôle ComboBox spécifié

#include <GuiComboBoxEx.au3>
_GUICtrlComboBoxEx_GetComboBoxInfo ( $hWnd, ByRef $tInfo )

Paramètres

$hWnd Handle du contrôle
$tInfo Structure qui va recevoir les informations sur le ComboBox.

Valeur de retour

Succès: Retourne True.
Échec: Retourne False.

Exemple

#include <GuiComboBoxEx.au3>
#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $hGUI, $tInfo, $hCombo

    ; Crée une GUI
    $hGUI = GUICreate("ComboBoxEx Get ComboBox Info", 400, 300)
    $hCombo = _GUICtrlComboBoxEx_Create($hGUI, "", 2, 2, 394, 100)
    GUISetState(@SW_SHOW)

    ; Ajoute des fichiers
    _GUICtrlComboBoxEx_AddDir($hCombo, "", $DDL_DRIVES, False)
    _GUICtrlComboBoxEx_AddDir($hCombo, "", $DDL_DRIVES)
    _GUICtrlComboBoxEx_BeginUpdate($hCombo)
    _GUICtrlComboBoxEx_AddDir($hCombo, @WindowsDir & "\*.exe")
    _GUICtrlComboBoxEx_EndUpdate($hCombo)

    If _GUICtrlComboBoxEx_GetComboBoxInfo($hCombo, $tInfo) Then _
            MsgBox($MB_SYSTEMMODAL, "Information", StringFormat("Edit Rect [%d][%d][%d][%d]", _
            DllStructGetData($tInfo, "EditLeft"), DllStructGetData($tInfo, "EditTop"), _
            DllStructGetData($tInfo, "EditRight"), DllStructGetData($tInfo, "EditBottom")))

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example