UDF > GDIPlus > Pen >

_GDIPlus_PenGetWidth

Récupére la largeur de tracé d'un crayon

#include <GDIPlus.au3>
_GDIPlus_PenGetWidth ( $hPen )

Paramètre

$hPen Handle de l'objet Pen

Valeur de retour

Succès: Retourne la largeur du crayon.
Échec: Retourne -1 et définit @error <> 0, @extended contient le code erreur GPSTATUS ($GPID_ERR*).

En relation

_GDIPlus_PenSetWidth

Voir aussi

Cherchez GdipGetPenWidth dans la Library MSDN.

Exemple

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $hGUI, $hGraphic, $hPen

    ; Crée une GUI
    $hGUI = GUICreate("GDI+", 400, 300)
    GUISetState(@SW_SHOW)

    ; Dessine une ligne
    _GDIPlus_Startup()
    $hGraphic = _GDIPlus_GraphicsCreateFromHWND($hGUI)
    $hPen = _GDIPlus_PenCreate(0xFF000000, 8)
    _GDIPlus_PenSetWidth($hPen, 4)
    _GDIPlus_GraphicsDrawLine($hGraphic, 10, 10, 390, 10, $hPen)

    ; Affiche la largeur du crayon
    MsgBox($MB_SYSTEMMODAL, "Information", "Pen Width: " & _GDIPlus_PenGetWidth($hPen))

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Nettoie les ressources
    _GDIPlus_PenDispose($hPen)
    _GDIPlus_GraphicsDispose($hGraphic)
    _GDIPlus_Shutdown()
EndFunc   ;==>Example