UDF > GDIPlus > Pen >

_GDIPlus_PenGetEndCap

Obtient le style d'embout de ligne affecté au crayon

#include <GDIPlus.au3>
_GDIPlus_PenGetEndCap ( $hPen )

Paramètre

$hPen Handle de l'objet Pen

Valeur de retour

Succès: Retourne le type d'embout:
    $GDIP_LINECAPFLAT - Embout plat
    $GDIP_LINECAPSQUARE - Embout carré
    $GDIP_LINECAPROUND - Embout rond
    $GDIP_LINECAPTRIANGLE - Embout triangulaire
    $GDIP_LINECAPNOANCHOR - Les extrémités de la ligne ne sont pas ancrées
    $GDIP_LINECAPSQUAREANCHOR - Les extrémités de ligne sont ancrées avec un carré
    $GDIP_LINECAPROUNDANCHOR - Les extrémités de ligne sont ancrées avec un cercle
    $GDIP_LINECAPDIAMONDANCHOR - Les extrémités de ligne sont ancrées avec un losange
    $GDIP_LINECAPARROWANCHOR - Les extrémités de ligne sont ancrés à l'aide d'embout de flèche
    $GDIP_LINECAPCUSTOM - les extrémités de ligne sont définies à partir d'un CustomLineCap
Échec: Retourne -1 et définit @error <> 0, @extended contient le code erreur GPSTATUS ($GPID_ERR*).

En relation

_GDIPlus_PenSetEndCap

Voir aussi

Cherchez GdipGetPenEndCap dans la Library MSDN.

Exemple

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $hGUI, $hGraphic, $hPen

    ; Crée une GUI
    $hGUI = GUICreate("GDI+", 400, 300)
    GUISetState(@SW_SHOW)

    ; Crée des ressources
    _GDIPlus_Startup()
    $hGraphic = _GDIPlus_GraphicsCreateFromHWND($hGUI)
    $hPen = _GDIPlus_PenCreate(0xFF000000, 8)
    _GDIPlus_PenSetEndCap($hPen, $GDIP_LINECAPARROWANCHOR)

    ; Affiche l'embout du crayon
    MsgBox($MB_SYSTEMMODAL, "Information", "Pen end cap type: " & _GDIPlus_PenGetEndCap($hPen))

    ; Dessine des flèches
    _GDIPlus_GraphicsDrawLine($hGraphic, 10, 130, 390, 130, $hPen)
    _GDIPlus_PenSetWidth($hPen, 6)
    _GDIPlus_GraphicsDrawLine($hGraphic, 10, 150, 390, 150, $hPen)
    _GDIPlus_PenSetWidth($hPen, 8)
    _GDIPlus_GraphicsDrawLine($hGraphic, 10, 170, 390, 170, $hPen)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Nettoie les ressources
    _GDIPlus_PenDispose($hPen)
    _GDIPlus_GraphicsDispose($hGraphic)
    _GDIPlus_Shutdown()
EndFunc   ;==>Example