UDF > GDIPlus > Pen >

_GDIPlus_PenGetCustomEndCap

Obtient l'embout personnalisé d'un crayon

#include <GDIPlus.au3>
_GDIPlus_PenGetCustomEndCap ( $hPen )

Paramètre

$hPen Handle de l'objet Pen

Valeur de retour

Succès: Retourne le handle d'un objet CustomLineCap qui caractèrise l'embout personnalisé du crayon.
Échec: Retourne 0 et définit @error <> 0, @extended contient le code erreur GPSTATUS ($GPID_ERR*).

En relation

_GDIPlus_PenSetCustomEndCap

Voir aussi

Cherchez GdipGetPenCustomEndCap dans la Library MSDN.

Exemple

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $hGUI, $hGraphic, $hPen, $hEndCap

    ; Crée une GUI
    $hGUI = GUICreate("GDI+", 400, 300)
    GUISetState(@SW_SHOW)

    ; Crée des ressources
    _GDIPlus_Startup()
    $hGraphic = _GDIPlus_GraphicsCreateFromHWND($hGUI)
    $hPen = _GDIPlus_PenCreate(0xFF000000, 4)
    $hEndCap = _GDIPlus_ArrowCapCreate(3, 6)
    _GDIPlus_PenSetCustomEndCap($hPen, $hEndCap)

    ; Affiche l'embout du crayon
    MsgBox($MB_SYSTEMMODAL, "Information", "Pen end cap: " & _GDIPlus_PenGetCustomEndCap($hPen))

    ; Dessine des flèches
    _GDIPlus_GraphicsDrawLine($hGraphic, 10, 120, 390, 120, $hPen)
    _GDIPlus_PenSetWidth($hPen, 6)
    _GDIPlus_GraphicsDrawLine($hGraphic, 10, 150, 390, 150, $hPen)
    _GDIPlus_PenSetWidth($hPen, 8)
    _GDIPlus_GraphicsDrawLine($hGraphic, 10, 200, 390, 200, $hPen)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Nettoie les ressources
    _GDIPlus_PenDispose($hPen)
    _GDIPlus_GraphicsDispose($hGraphic)
    _GDIPlus_Shutdown()
EndFunc   ;==>Example