UDF > GDIPlus > GraphicsPath >

_GDIPlus_PathStartFigure

Démarre une nouvelle figure sans fermer la figure actuelle. Les points ajoutés au tracé sont alors ajoutés à la nouvelle figure

#include <GDIPlus.au3>
_GDIPlus_PathStartFigure ( $hPath )

Paramètre

$hPath Handle de l'objet GraphicsPath

Valeur de retour

Succès: Retourne True.
Échec: Retourne False et définit @error <> 0, @extended contient le code erreur ($GPID_ERR*).

En relation

_GDIPlus_PathCloseFigure

Voir aussi

Consultez GdipStartPathFigure dans la Librairie MSDN.

Exemple

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>

Example()

Func Example()
    Local $hGUI, $hGraphic, $hPen, $hPath

    ; Crée une GUI
    $hGUI = GUICreate("GDI+", 800, 300)
    GUISetState(@SW_SHOW)

    _GDIPlus_Startup()
    $hGraphic = _GDIPlus_GraphicsCreateFromHWND($hGUI) ; Crée un objet graphique à partir du handle de la fenêtre
    _GDIPlus_GraphicsSetSmoothingMode($hGraphic, $GDIP_SMOOTHINGMODE_HIGHQUALITY) ; Définit pour l'objet graphique la qualité de rendu antialiasing
    _GDIPlus_GraphicsClear($hGraphic, 0xFFFFFFFF)

    $hPen = _GDIPlus_PenCreate(0xFF8800AA, 2)

    $hPath = _GDIPlus_PathCreate() ; Crée un objet path

    _GDIPlus_PathAddLine($hPath, 40, 100, 140, 200)
    _GDIPlus_PathAddLine($hPath, 240, 100, 340, 200)

    _GDIPlus_PathStartFigure($hPath); La ligne suivante ne sera pas reliée au dernier point

    _GDIPlus_PathAddLine($hPath, 440, 100, 540, 200)
    _GDIPlus_PathAddLine($hPath, 640, 100, 740, 200)

    _GDIPlus_GraphicsDrawPath($hGraphic, $hPath, $hPen)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Nettoie les ressources
    _GDIPlus_PathDispose($hPath)
    _GDIPlus_PenDispose($hPen)
    _GDIPlus_GraphicsDispose($hGraphic)
    _GDIPlus_Shutdown()
EndFunc   ;==>Example