UDF > GDIPlus > Image >

_GDIPlus_ImageGetPropertyItem

Obtient un élément de propriété spécifié (partie de méta donnée) d'un objet Image

#include <GDIPlus.au3>
_GDIPlus_ImageGetPropertyItem ( $hImage, $iPropID )

Paramètres

$hImage Le handle de l'objet Image.
$iPropID Un identifiant d'élément de propriété à récupérer.

Valeur de retour

Succès: Retourne le tableau qui contient les valeurs de l'élément de propriété:
    [0] - Nombre de valeurs
    [1] - Valeur 1
    [2] - Valeur 2
    [n] - Valeur n
Échec: Définit @error <> 0, @extended peut contenir le code d'erreur GPSTATUS ($GPID_ERR*).

En relation

_GDIPlus_ImageGetPropertyIdList

Voir aussi

Consultez GdipGetPropertyItem dans la librairie MSDN.

Exemple

#include <Array.au3>
#include <GDIPlus.au3>

Example()

Func Example()
    _GDIPlus_Startup()
    Local $hImage = _GDIPlus_ImageLoadFromFile(RegRead((@AutoItX64 = True ? "HKLM\SOFTWARE\Wow6432Node\AutoIt v3\AutoIt" : "HKLM\SOFTWARE\AutoIt v3\AutoIt"), "InstallDir") & "\Examples\GUI\Torus.png")
    If @error Then
        _GDIPlus_Shutdown()
        MsgBox(16, "", "Une erreur est survenue - impossible de charger l'image!", 30)
        Return False
    EndIf

    Local $aPropID = _GDIPlus_ImageGetPropertyIdList($hImage)
    _ArrayDisplay($aPropID)

    Local $aValues
    For $i = 1 To $aPropID[0][0]
        $aValues = _GDIPlus_ImageGetPropertyItem($hImage, $aPropID[$i][0])
        _ArrayDisplay($aValues, $aPropID[$i][1])
    Next

    _GDIPlus_ImageDispose($hImage)
    _GDIPlus_Shutdown()
EndFunc   ;==>Example