UDF > GDIPlus > Image >

_GDIPlus_ImageGetPropertyIdList

Obtient une liste d'identifiants de propriété utilisés dans les méta données d'un objet Image

#include <GDIPlus.au3>
_GDIPlus_ImageGetPropertyIdList ( $hImage )

Paramètre

$hImage Le handle de l'objet Image.

Valeur de retour

Succès: Retourne le tableau des identifiants de propriété:
    [0][0] - Nombre d'identifiants de propriété
    [1][0] - Identifiant de propriété 1
    [1][1] - Property ID Info 1
    [2][0] - Identifiant de propriété 2
    [2][1] - Property ID Info 2
    [n][0] - Identifiant de propriété n
    [n][1] - Property ID Info n
Échec: Définit @error <> 0, @extended peut contenir le code d'erreur GPSTATUS ($GPID_ERR*).

Voir aussi

Consultez GdipGetPropertyCount dans la librairie MSDN.

Exemple

#include <Array.au3>
#include <GDIPlus.au3>

Example()

Func Example()
    _GDIPlus_Startup()
    Local $hImage = _GDIPlus_ImageLoadFromFile(RegRead((@AutoItX64 = True ? "HKLM\SOFTWARE\Wow6432Node\AutoIt v3\AutoIt" : "HKLM\SOFTWARE\AutoIt v3\AutoIt"), "InstallDir") & "\Examples\GUI\Torus.png")
    If @error Then
        _GDIPlus_Shutdown()
        MsgBox(16, "", "Une erreur est survenue - impossible de charger l'image!", 30)
        Return False
    EndIf

    Local $aPropID = _GDIPlus_ImageGetPropertyIdList($hImage)
    _ArrayDisplay($aPropID)

    Local $aValues
    For $i = 1 To $aPropID[0][0]
        $aValues = _GDIPlus_ImageGetPropertyItem($hImage, $aPropID[$i][0])
        _ArrayDisplay($aValues, $aPropID[$i][1])
    Next

    _GDIPlus_ImageDispose($hImage)
    _GDIPlus_Shutdown()
EndFunc   ;==>Example