UDF > GDIPlus > Graphics >

_GDIPlus_GraphicsSetTextRenderingHint

Définit la valeur du contraste d'un objet Graphics

#include <GDIPlus.au3>
_GDIPlus_GraphicsSetTextRenderingHint ( $hGraphics, $iTextRenderingHint )

Paramètres

$hGraphics Handle de l'objet Graphics
$iTextRenderingHint Mode de rendu de texte:
    0 - Un caractère est dessiné en utilisant le mode de lissage des polices du système actuellement sélectionné (aussi appelé 'rendu système')
    1 - Un caractère est dessiné en utilisant le bitmap de son glyphe et en tentant d'améliorer l'apparence du caractère
    2 - Un caractère est dessiné en utilisant le bitmap de son glyphe sans chercher à améliorer. Il en résulte de meilleures performances au détriment de la qualité
    3 - Un caractère est dessiné en utilisant le bitmap de son glyphe lissé et amélioré. Il en résulte une bien meilleure qualité
    4 - Un caractère est dessiné en utilisant le bitmap de son glyphe lissé (anti-crénelage) mais pas amélioré. Des différences de largeur des jambes peuvent être perceptible
    5 - Un caractère est dessiné à l'aide du bitmap de son glyphe Microsoft ClearType avec amélioration.

Valeur de retour

Succès: Retourne True.
Échec: Retourne False et définit @error <> 0, @extended contient le code erreur GPSTATUS ($GPID_ERR*).

Voir aussi

Consultez GdipSetTextRenderingHint dans la Librairie MSDN.

Exemple

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $hGUI = GUICreate("GDI+ test", 800, 400)
    GUISetState(@SW_SHOW)

    If @OSBuild < 6000 Then MsgBox($MB_SYSTEMMODAL, "", "Antialiasing is automatically turned on for your operating system - no visible differences!")

    _GDIPlus_Startup()
    Local $hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGUI)
    _GDIPlus_GraphicsDrawString($hGraphics, "AutoIt rulez!", 0, 0, "Impact", 110)
    _GDIPlus_GraphicsSetTextRenderingHint($hGraphics, $GDIP_TEXTRENDERINGHINT_ANTIALIASGRIDFIT)
    _GDIPlus_GraphicsDrawString($hGraphics, "AutoIt rulez!", 0, 200, "Impact", 110)

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE 

    ; Nettoie
    _GDIPlus_GraphicsDispose($hGraphics)
    _GDIPlus_Shutdown()
    GUIDelete($hGUI)
EndFunc   ;==>Example