UDF > GDIPlus > Graphics >

_GDIPlus_GraphicsDrawPie

Dessine un secteur d'angle d'ellipse

#include <GDIPlus.au3>
_GDIPlus_GraphicsDrawPie ( $hGraphics, $nX, $nY, $nWidth, $nHeight, $fStartAngle, $fSweepAngle [, $hPen = 0] )

Paramètres

$hGraphics Handle de l'objet Graphics
$nX La coordonnée X du coin supérieur gauche du rectangle qui délimite l'ellipse qui contient le secteur d'angle
$nY La coordonnée Y du coin supérieur gauche du rectangle qui délimite l'ellipse qui contient le secteur d'angle
$nWidth La largeur du rectangle qui délimite l'ellipse qui contient le secteur d'angle
$nHeight La hauteur du rectangle qui délimite l'ellipse contient le secteur d'angle
$fStartAngle L'angle, en degrés, entre l'axe X et le point de l'arc qui définit le départ du secteur.
Une valeur positive indique une rotation dans le sens horaire.
$fSweepAngle L'angle, en degrés, entre les points de départ et de fin de l'arc qui définit le secteur.
Une valeur positive indique une rotation dans le sens horaire.
$hPen [optionnel] Handle de l'objet Pen qui sera utilisé pour dessiner le secteur. Si 0, un crayon noir qui trace des traits continus de largeur de 1 sera utilisé.

Valeur de retour

Succès: Retourne True.
Échec: Retourne False et définit @error <> 0, @extended contient le code erreur GPSTATUS ($GPID_ERR*).

Voir aussi

Consultez GdipDrawPie dans la Librairie MSDN.

Exemples

Exemple 1

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>

Example()

Func Example()
    Local $hGUI, $hGraphic

    ; Crée une fenêtre
    $hGUI = GUICreate("GDI+", 400, 300)
    GUISetState(@SW_SHOW)

    ; Dessine un secteur d'angle (morceau de  tarte)
    _GDIPlus_Startup()
    $hGraphic = _GDIPlus_GraphicsCreateFromHWND($hGUI)
    _GDIPlus_GraphicsDrawPie($hGraphic, 150, 80, 100, 100, 45, 90)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Nettoie les ressources
    _GDIPlus_GraphicsDispose($hGraphic)
    _GDIPlus_Shutdown()
EndFunc   ;==>Example

Exemple 2

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>

Example()

Func Example()
    _GDIPlus_Startup() ; Initialise GDI+
    Local Const $iWidth = 600, $iHeight = 600, $iBgColor = 0x303030 ; $iBGColor est au format RRGGBB

    Local $hGUI = GUICreate("GDI+ example", $iWidth, $iHeight) ; Crée une fenêtre de test
    GUISetBkColor($iBgColor, $hGUI) ; Définit la couleur de fond de la GUI
    GUISetState(@SW_SHOW)

    Local $hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGUI) ; Crée un objet Graphics à partir du handle de la fenêtre
    _GDIPlus_GraphicsSetSmoothingMode($hGraphics, $GDIP_SMOOTHINGMODE_HIGHQUALITY) ; Définit pour l'objet graphique la qualité de rendu antialiasing
    Local $hPen = _GDIPlus_PenCreate(0xFFA08080, 2) ; Format de couleur AARRGGBB (hex)
    _GDIPlus_GraphicsDrawPie($hGraphics, 100.5, 0.5, 400.75, 400.125, 45, 90, $hPen)

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Nettoie les ressources GDI+
    _GDIPlus_PenDispose($hPen)
    _GDIPlus_GraphicsDispose($hGraphics)
    _GDIPlus_Shutdown()
    GUIDelete($hGUI)
EndFunc   ;==>Example