UDF > GDIPlus > Effect >

_GDIPlus_EffectCreateColorCurve

Crée un objet Effect qui agit sur la distorsion des couleurs

#include <GDIPlus.au3>
_GDIPlus_EffectCreateColorCurve ( $iAdjustment, $iChannel, $iAdjustValue )

Paramètres

$iAdjustment Constante CurveAdjustments qui spécifie l'ajustement à appliquer ($GDIP_Adjust*).
$iChannel Constante CurveChannel spécifie le canal de couleur auquel l'ajustement s'applique ($GDIP_CurveChannel*).
$iAdjustValue Entier qui spécifie l'intensité de l'ajustement.
La plage de valeurs acceptables dépend du réglage qui est appliquée (voir constantes $GDIP_Adjust*).

Valeur de retour

Succès: Retourne le handle de l'objet Effect.
Échec: Retourne 0 et définit @error <> 0, @extended contient le code erreur GPSTATUS ($GPID_ERR*).
@error: -1 - GDIPlus.dll ne supporte pas cette fonction.
10 - Paramètres invalides.

Remarque

Lorsque vous en avez terminé avec l'objet Effect, appelez _GDIPlus_EffectDispose() pour libérer les ressources.

En relation

_GDIPlus_EffectCreate, _GDIPlus_EffectDispose

Exemple

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>

_Example()

Func _Example()
    Local $sFile = FileOpenDialog("Sélectionnez une image", "", "Images (*.bmp;*.png;*.jpg;*.gif;*.tif)")
    If @error Or Not FileExists($sFile) Then Return

    If Not _GDIPlus_Startup() Then
        MsgBox($MB_SYSTEMMODAL, "ERROR", "GDIPlus.dll v1.1 not available")
        Return
    EndIf

    Local $hImage = _GDIPlus_ImageLoadFromFile($sFile)

    Local $iWidth = 600
    Local $iHeight = _GDIPlus_ImageGetHeight($hImage) * 600 / _GDIPlus_ImageGetWidth($hImage)

    Local $hGui = GUICreate("GDI+ v1.1", $iWidth, $iHeight)
    Local $hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGui)
    GUISetState(@SW_SHOW)

    Local $hEffect = _GDIPlus_EffectCreateColorCurve($GDIP_AdjustMidtone, $GDIP_CurveChannelRed, 30)
    _GDIPlus_BitmapApplyEffect($hImage, $hEffect)

    _GDIPlus_GraphicsDrawImageRect($hGraphics, $hImage, 0, 0, $iWidth, $iHeight)

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    _GDIPlus_EffectDispose($hEffect)
    _GDIPlus_ImageDispose($hImage)
    _GDIPlus_GraphicsDispose($hGraphics)
    _GDIPlus_Shutdown()
EndFunc   ;==>_Example