UDF > GDIPlus > ArrowCap >

_GDIPlus_ArrowCapSetWidth

Définit la largeur de l'embout d'une flèche

#include <GDIPlus.au3>
_GDIPlus_ArrowCapSetWidth ( $hArrowCap, $fWidth )

Paramètres

$hArrowCap Handle de l'embout de flèche
$fWidth Spécifie la distance entre les coins de la base de l'embout; l'unité est l'épaisseur du crayon.

Valeur de retour

Succès: Retourne True
Échec: Retourne False et définit @error <> 0, @extended contient le code erreur GPSTATUS ($GPID_ERR*)

En relation

_GDIPlus_ArrowCapGetWidth

Voir aussi

Consultez GdipSetAdjustableArrowCapWidth dans la Library MSDN

Exemple

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>

Example()

Func Example()
    Local $hGUI, $hGraphic, $hPen, $hEndCap

    ; Crée GUI
    $hGUI = GUICreate("GDI+", 400, 300)
    GUISetState(@SW_SHOW)

    ; Crée des ressources
    _GDIPlus_Startup()
    $hGraphic = _GDIPlus_GraphicsCreateFromHWND($hGUI)
    $hPen = _GDIPlus_PenCreate(0xFF000000, 4)
    $hEndCap = _GDIPlus_ArrowCapCreate(3, 6)
    _GDIPlus_PenSetCustomEndCap($hPen, $hEndCap)

    ; Dessine flèche 1
    _GDIPlus_GraphicsDrawLine($hGraphic, 10, 120, 390, 120, $hPen)

    ; Dessine flèche 2
    _GDIPlus_ArrowCapSetWidth($hEndCap, _GDIPlus_ArrowCapGetWidth($hEndCap) + 2)
    _GDIPlus_PenSetCustomEndCap($hPen, $hEndCap)
    _GDIPlus_GraphicsDrawLine($hGraphic, 10, 150, 390, 150, $hPen)

    ; Dessine flèche 3
    _GDIPlus_ArrowCapSetWidth($hEndCap, _GDIPlus_ArrowCapGetWidth($hEndCap) + 2)
    _GDIPlus_PenSetCustomEndCap($hPen, $hEndCap)
    _GDIPlus_GraphicsDrawLine($hGraphic, 10, 190, 390, 190, $hPen)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Nettoie les ressources
    _GDIPlus_ArrowCapDispose($hEndCap)
    _GDIPlus_PenDispose($hPen)
    _GDIPlus_GraphicsDispose($hGraphic)
    _GDIPlus_Shutdown()
EndFunc   ;==>Example