UDF > GDIPlus > ArrowCap >

_GDIPlus_ArrowCapSetMiddleInset

Définit la valeur du déport de l'embout de flèche

#include <GDIPlus.au3>
_GDIPlus_ArrowCapSetMiddleInset ( $hArrowCap, $fInset )

Paramètres

$hArrowCap Handle de l'objet embout de flèche
$fInset Valeur du déport

Valeur de retour

Succès: Retourne True
Échec: Retourne False et définit @error <> 0, @extended contient le code erreur GPSTATUS ($GPID_ERR * ).

Remarques

Le déport est le nombre d'unités qui mesure le déplacement du milieu de la base vers la pointe.

Un déport de zéro n'entraîne pas de changement, la base est une ligne droite, donnant à l'embout de la flèche une forme triangulaire.
Un déport positif (supérieur à zéro) entraîne un déplacement du milieu de la base, du nombre spécifié d'unités, vers la pointe, la base prend la forme d'une flèche dirigée vers la pointe, donnant à l'embout de flèche une forme en V.
Un déport négatif (inférieur à zéro) entraine un déplacement du milieu de la base, du nombre spécifié d'unités, dans la direction opposé à la pointe — la base devient une forme de flèche qui dirigée à l'opposé de la pointe, donnant à la flèche la forme d'un losange (si la valeur absolue du déport est égale à la hauteur) ou d'un losange déformée.
Si le déport est égal ou supérieure à la hauteur de l'embout de flèche, l'embout ne s'affiche pas du tout.
La valeur du déport du milieu n'affecte l'embout de flèche que si l'embout est rempli'.

En relation

_GDIPlus_ArrowCapGetMiddleInset

Voir aussi

Consultez GdipSetAdjustableArrowCapMiddleInset dans la Library MSDN.

Exemple

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>

Example()

Func Example()
    Local $hGUI, $hGraphic, $hPen, $hEndCap, $iInset

    ; Crée GUI
    $hGUI = GUICreate("GDI+", 400, 300)
    GUISetState(@SW_SHOW)

    ; Crée des ressources
    _GDIPlus_Startup()
    $hGraphic = _GDIPlus_GraphicsCreateFromHWND($hGUI)
    $hPen = _GDIPlus_PenCreate(0xFF000000, 4)
    $hEndCap = _GDIPlus_ArrowCapCreate(3, 6)

    ; Dessine flèche 1
    $iInset = 0.5
    _GDIPlus_ArrowCapSetMiddleInset($hEndCap, $iInset)
    _GDIPlus_PenSetCustomEndCap($hPen, $hEndCap)
    _GDIPlus_GraphicsDrawLine($hGraphic, 10, 120, 390, 120, $hPen)

    ; Dessine flèche 2
    $iInset = _GDIPlus_ArrowCapGetMiddleInset($hEndCap) + 0.5
    _GDIPlus_ArrowCapSetMiddleInset($hEndCap, $iInset)
    _GDIPlus_PenSetCustomEndCap($hPen, $hEndCap)
    _GDIPlus_GraphicsDrawLine($hGraphic, 10, 150, 390, 150, $hPen)

    ; Dessine flèche 3
    $iInset = _GDIPlus_ArrowCapGetMiddleInset($hEndCap) + 0.5
    _GDIPlus_ArrowCapSetMiddleInset($hEndCap, $iInset)
    _GDIPlus_PenSetCustomEndCap($hPen, $hEndCap)
    _GDIPlus_GraphicsDrawLine($hGraphic, 10, 180, 390, 180, $hPen)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Nettoie les ressources
    _GDIPlus_ArrowCapDispose($hEndCap)
    _GDIPlus_PenDispose($hPen)
    _GDIPlus_GraphicsDispose($hGraphic)
    _GDIPlus_Shutdown()
EndFunc   ;==>Example