Mot-clés AutoIt


ContinueCase

Abandonne le "case" en cours et passe au suivant dans une condition Select ou Switch.

ContinueCase

Remarques

Normalement, dans une condition Select ou Switch, un bloc "case" prend fin lorsque la déclaration "case" suivante est rencontrée. Lors de l'exécution de ContinueCase, AutoIt s'arrêtera d'exécuter le bloc "case" en cours et exécutera le "case" suivant.

Si vous essayez d'exécuter un "case" hors d'une condition Select ou Swtich vous provoquerez une erreur fatale.

En relation

Select...EndSelect, Switch...EndSwitch

Exemple

#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $sName = InputBox("", "SVP, tapez un mot.", "", " M", Default, Default, Default, Default, 10)
    Local $sMsg = ""

    Switch @error
        Case 2
            $sMsg = "Hors délai "
            ContinueCase
        Case 1 ; Suite du case précédent
            $sMsg &= "Annulation"
        Case 0
            Switch $sName
                Case "a", "e", "i", "o", "u"
                    $sMsg = "Voyelles"
                Case "QP"
                    $sMsg = "Mathematiques"
                Case "Q" To "QZ"
                    $sMsg = "Science"
                Case Else
                    $sMsg = "Autres"
            EndSwitch
        Case Else
            $sMsg = "Quelque chose a mal tourné!"
    EndSwitch

    MsgBox($MB_SYSTEMMODAL, "", $sMsg)
EndFunc   ;==>Example