Functions > Map >

MapRemove

Supprime une clé et sa valeur dans une table.

MapRemove ( map, key )

Paramètres

map Une table existante
key La clé à supprimer

Valeur de retour

Succès: Retourne 1
Echec: Retourne 0 et définit @error <> 0

Remarques

Presque uniquement dans AutoIt, les clés sont sensibles à la casse - "MyKey" n'est pas la même clé que "mykey".

Les fonctions Map ne sont pas disponibles dans la version AutoIt 3.3.14.5 mais peuvent être testées dans la version Béta (Alt-F5).

En relation

MapAppend

Exemple

#include  <MsgBoxConstants.au3>

Example()

Func Example()
    ; Déclare une table et l'assigne avec des paires de clé/valeur.
    Local $mMap[]
    $mMap["Jasper"] = "Jasper value"
    $mMap["Beethoven"] = "Beethoven value"
    $mMap["Pinky"] = "Pinky value"

    ; Lit les clés
    Local $aKeys = MapKeys($mMap)
    Local $sData = ""
    ; Lit les valeurs
    For $i = 0 To UBound($aKeys) - 1
        $sData &= $aKeys[$i] & ": " & $mMap[$aKeys[$i]] & @CRLF
    Next
    ; Affiche le résultat
    MsgBox($MB_SYSTEMMODAL, "", $sData & @CRLF & _
            'Beethoven existe? ' & MapExists($mMap, "Beethoven") & @CRLF & 'Beethoven est Null? ' & ($mMap["Beethoven"] == Null))

    ; Efface une clé en la définissant à Null. La clé existera encore dans la table.
    $mMap["Beethoven"] = Null

    ; Re-lit les clés et les valeurs
    $aKeys = MapKeys($mMap)
    $sData = ""
    For $i = 0 To UBound($aKeys) - 1
        $sData &= $aKeys[$i] & ": " & $mMap[$aKeys[$i]] & @CRLF
    Next
    ; Affiche les valeurs des clés de la table. Notez que la clé "Beethoven" contient maintenant une valeur vide (Null).
    MsgBox($MB_SYSTEMMODAL, "", $sData & @CRLF & _
            'Beethoven existe? ' & MapExists($mMap, "Beethoven") & @CRLF & 'Beethoven est Null? ' & ($mMap["Beethoven"] == Null))

    ; Supprime la clé "Beethoven" entièrement.
    MapRemove($mMap, "Beethoven")

    ; Re-lit les clés et les valeurs
    $aKeys = MapKeys($mMap)
    $sData = ""
    For $i = 0 To UBound($aKeys) - 1
        $sData &= $aKeys[$i] & ": " & $mMap[$aKeys[$i]] & @CRLF
    Next
    ; Affiche les valeurs des clés de la table. Notez que la clé "Beethoven" n'existe plus.
    MsgBox($MB_SYSTEMMODAL, "", $sData & @CRLF & _
            'Beethoven existe? ' & MapExists($mMap, "Beethoven") & @CRLF & 'Beethoven est Null? ' & ($mMap["Beethoven"] == Null))

EndFunc   ;==>Example