Functions > VarConv >

IsFunc

Détermine si une variable ou une expression est du type fonction.

IsFunc ( expression )

Paramètre

expression La variable ou l'expression à analyser.

Valeur de retour

Succès: Retourne 1 si la variable est une fonction définie par l'utilisateur, 2 si la variable est une fonction native.
Échec: Retourne 0 si l'expression n'est pas du type fonction.

Remarque

Consultez Types de Données du Langage pour une description détaillée.

En relation

Binary, BinaryToString, IsArray, IsBool, IsFloat, IsHWnd, IsInt, IsNumber, IsString, StringToBinary, VarGetType

Exemples

Exemple 1

#include <MsgBoxConstants.au3>

Example()

Func Example()
    ; Crée un premier objet de la classe de MsgBox et assigner à une variable locale.
    Local $hMsgBox = MsgBox

    ; Affiche une MsgBox en utilisant la variable précédemment attribuée.
    $hMsgBox($MB_SYSTEMMODAL, "", "This is a sentence with whitespace.")

    ; Affiche une MsgBox qui montre $hMsgBox est une fonction native.
    $hMsgBox($MB_SYSTEMMODAL, "", "Check if $hMsgBox is a function or not." & @CRLF & _
            @CRLF & _
            "This will return 1 as the function is native: " & IsFunc($hMsgBox))
EndFunc   ;==>Example

Exemple 2

#include <MsgBoxConstants.au3>

Example()

Func Example()
    ; Crée un premier objet de la classe de MsgBox et assigner à une variable locale.
    Local $hMsgBox = MsgBox

    ; Affiche une MsgBox en utilisant la variable précédemment attribuée.
    $hMsgBox($MB_SYSTEMMODAL, "", "Ceci est une phrase avec espaces.")

    ; Ré-assigne la variable $hMsgBox avec notre fonction de boîte de message défini par l'utilisateur.
    $hMsgBox = MyMsgBox

    ; Affiche une MsgBox qui montre que $hMsgBox est une fonction.
    $hMsgBox($MB_SYSTEMMODAL, "", "Teste si $hMsgBox est une fonction ou pas." & @CRLF & _
            @CRLF & _
            "Retourne 2 car la fonction est une fonction-utilisateur: " & IsFunc($hMsgBox))
EndFunc   ;==>Example

; Fonction boîte de message définie par l'utilisateur.
Func MyMsgBox($iFlag, $sTitle, $sText = "")
    Return MsgBox($iFlag, $sTitle, $sText)
EndFunc   ;==>MyMsgBox