Functions > FileDirDisk >

FileSelectFolder

Ouvre une boîte de dialogue de sélection de dossier.

FileSelectFolder ( "dialog text", "root dir" [, flag = 0 [, "initial dir" [, hwnd]]] )

Paramètres

dialog text Texte du message d'accueil de la boîte de dialogue.
root dir Répertoire racine de l'arborescence des fichiers proposés. Utilisez "" pour que le bureau soit le répertoire racine.
flag [optionnel]
    $FSF_CREATEBUTTON (1) = Affiche un bouton de création de dossier (XP seulement)
    $FSF_NEWDIALOG (2)= Utilise un style de dialogue nouveau (XP seulement)
    $FSF_EDITCONTROL (4) = Affiche un contrôle Edit (XP seulement)

Les constantes sont définies dans FileConstants.au3.
initial dir [optionnel] Le chemin complet du dossier sélectionné (mis en surbrillance) lors de l'affichage de la boîte de dialoque (s'il existe dans le dossier racine). Par défaut, vide ("").
hwnd [optionnel] Le handle de la fenêtre à utiliser comme parent pour cette boite de dialogue.

Valeur de retour

Succès: Retourne le chemin complet du dossier choisi.
Échec: Renvoie "" (chaîne vide) et @error = 1 si l'utilisateur annule/ferme le dialogue.

Remarque

Le répertoire racine sera choisi si le dossier initial (si donnée en paramètre) n'existe pas.
Un répertoire racine inexistant entraînera également que le dossier Bureau soit le répertoire racine.
Les dossiers Windows spéciaux (tels que "Mes Documents") peuvent être définis en tant que root en utilisant le bon CLSID détaillée dans l'Appendice.
Les chemins UNC ne sont pas pris en charge. Si vous pensez que l'utilisateur peut avoir besoin de choisir les fichiers sur un chemin UNC, le chemin doit être mappé comme un premier disque.

Le nouveau style de dialogue de Vista+ est utilisé si possible, suivant le flag Use New Dialog Style. Avec le style de dialogue de Vista le contrôle edit et les boutons de création de dossier sont toujours affichés, ignorant les paramètres flag, et le paramètre texte du dialogue définit le titre de la fenêtre.

En relation

FileOpenDialog, FileSaveDialog

Exemple

#include <MsgBoxConstants.au3>

Example()

Func Example()
    ; Crée une constante locale avec le message à afficher dans FileSelectFolder.
    Local Const $sMessage = "Choisissez un dossier"

    ; Ouvre une boîte de dialogue pour sélectionner un dossier.
    Local $sFileSelectFolder = FileSelectFolder($sMessage, "")
    If @error Then
        ; Affiche le message d'erreur.
        MsgBox($MB_SYSTEMMODAL, "", "Aucun dossier n'a été sélectionné.")
    Else
        ; Affiche le dossier sélectionné.
        MsgBox($MB_SYSTEMMODAL, "", "Vous avez choisi le dossier suivant:" & @CRLF & $sFileSelectFolder)
    EndIf
EndFunc   ;==>Example