Functions > FileDirDisk >

FileCreateShortcut

Crée un raccourci (.lnk) vers un fichier.

FileCreateShortcut ( "file", "lnk" [, "workdir" [, "args" [, "desc" [, "icon" [, "hotkey" [, icon number [, state]]]]]]] )

Paramètres

file Chemin complet et nom du fichier sur lequel pointera le raccourci.
lnk Chemin complet et nom du raccourci.
workdir [optionnel] Répertoire de travail.
args [optionnel] Arguments additionnels du fichier.
desc [optionnel] Description du fichier
icon [optionnel] Chemin complet et nom de l'icône à utiliser.
hotkey [optionnel] Touche de raccourci - même format de touche que pour la fonction Send()
icon number [optionnel] Instance de l'icône à utiliser (généralement 0).
state [optionnel] L'état dans lequel le raccourci est lancé. Utilisez @SW_SHOWNORMAL, @SW_SHOWMINNOACTIVE ou @SW_SHOWMAXIMIZED

Valeur de retour

Succès: Retourne 1.
Échec: Retourne 0 si le raccourci n'a pu être créé.

Remarques

Les raccourcis clavier sous Windows sont de la forme: Ctrl+Alt+X, Ctrl+Shift+X, Shift+Alt+X, Ctrl+NumPadKey, ou Alt+NumPadKey où X représente une lettre, un nombre, une ponctuation, ou une touche de fonction. Si vous spécifiez une forme invalide, Windows utilisera Ctrl+Alt par défaut
Notez que Windows distingue les chiffres du pavé numérique des chiffres standards ainsi que les touches de ponctuation. FileCreateShortcut() vous autorise de créer des raccourcis clavier Ctrl+X et Alt+X (alors que Windows n'autorise X que s'il est un chiffre du pavé numérique); cependant, vous devriez éviter ce genre d'assignation, car il pourrait entrer en conflit avec des raccourcis clavier standards.
Windows interdit l'utilisation de ESC, ENTER, TAB, SPACEBAR, PRINT SCREEN, SHIFT, ou BACKSPACE dans les raccourcis clavier.

FileCreateShortcut() ne nécessite pas que la cible soit valide, le répertoire de travail, l'icône, ou le raccourci clavier crée avec succès un fichier LNK; cependant, la destination du fichier LNK doit d'être valide! Si le raccourci clavier que vous choisissez existe déjà, votre nouveau raccourci aura la priorité. De plus, si vous créez un raccourci avec le même chemin/nom qu'un raccourci précédent, ce dernier sera remplacé par votre nouvelle version.

En relation

FileCreateNTFSLink, FileGetShortcut

Exemple

#include <MsgBoxConstants.au3>

Example()

Func Example()
    ; Crée une constante locale avec le nom complet du fichier de raccourci.
    Local Const $sFilePath = @DesktopDir & "\FileCreateShortcutExample.lnk"

    ; Crée un raccourci sur le bureau pour explorer.exe et définit la combinaison de touches Ctrl+Alt+T ou dans AutoIt ^!t au raccourci.
    FileCreateShortcut(@WindowsDir & "\explorer.exe", $sFilePath, @WindowsDir, "/e,c:\", _
            "Description du raccourci.", @SystemDir & "\shell32.dll", "^!t", "15", @SW_SHOWMAXIMIZED)

    ; Obtient des caractéristiques du raccourci.
    Local $aDetails = FileGetShortcut($sFilePath)
    If Not @error Then
        MsgBox($MB_SYSTEMMODAL, "", "Path: " & $aDetails[0] & @CRLF & _
                "Répertoire de travail: " & $aDetails[1] & @CRLF & _
                "Arguments: " & $aDetails[2] & @CRLF & _
                "Description: " & $aDetails[3] & @CRLF & _
                "Nom de l'icône: " & $aDetails[4] & @CRLF & _
                "Index de l'icône: " & $aDetails[5] & @CRLF & _
                "Etat du raccourci: " & $aDetails[6] & @CRLF)
    EndIf

    ; Supprime le raccourci.
    FileDelete($sFilePath)
EndFunc   ;==>Example