UDF > GUI > GuiScrollBars >


_GUIScrollBars_GetScrollInfo

Obtient les paramètres d'une barre de défilement dans une structure

#include <GuiScrollBars.au3>
_GUIScrollBars_GetScrollInfo ( $hWnd, $iBar, ByRef $tSCROLLINFO )

Paramètres

$hWnd Le handle de la fenêtre
$iBar Spécifie le type de barre de défilement. Ce paramètre peut prendre l'une des valeurs suivantes:
    $SB_CTL - Obtient les paramètres pour un contrôle de barre de défilement. Le paramètre $hWnd doit être le handle du contrôle de la barre de défilement.
    $SB_HORZ - Obtient les paramètres de la barre de défilement horizontale standard de la fenêtre.
    $SB_VERT - Obtient les paramètres de la barre de défilement verticale standard de la fenêtre.
$tSCROLLINFO Structure de type $tagSCROLLINFO

Valeur de retour

Succès: Retourne True, ...et la structure byref.
Échec: Retourne False.

En relation

$tagSCROLLINFO, _GUIScrollBars_GetScrollInfoEx, _GUIScrollBars_SetScrollInfo

Voir aussi

Consultez GetScrollInfo dans la librairie MSDN.

Exemple

#include <GUIConstantsEx.au3>
#include <GuiScrollBars.au3>
#include <StructureConstants.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $hGUI, $tSCROLLINFO = DllStructCreate($tagSCROLLINFO)

    $hGUI = GUICreate("ScrollBar Example", 400, 400, -1, -1, BitOR($WS_MINIMIZEBOX, $WS_CAPTION, $WS_POPUP, $WS_SYSMENU, $WS_SIZEBOX))
    $g_idMemo = GUICtrlCreateEdit("", 2, 2, 380, 360, BitOR($WS_HSCROLL, $WS_VSCROLL))
    GUICtrlSetResizing($g_idMemo, $GUI_DOCKALL)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetBkColor(0x88AABB)

    GUISetState(@SW_SHOW)

    _GUIScrollBars_Init($hGUI)

    DllStructSetData($tSCROLLINFO, "cbSize", DllStructGetSize($tSCROLLINFO))
    DllStructSetData($tSCROLLINFO, "fMask", $SIF_ALL)
    _GUIScrollBars_GetScrollInfo($hGUI, $SB_HORZ, $tSCROLLINFO)
    MemoWrite("Horizontal" & @CRLF & "--------------------------------------")
    MemoWrite("nPage....: " & DllStructGetData($tSCROLLINFO, "nPage"))
    MemoWrite("nPos.....: " & DllStructGetData($tSCROLLINFO, "nPos"))
    MemoWrite("nMin.....: " & DllStructGetData($tSCROLLINFO, "nMin"))
    MemoWrite("nMax.....: " & DllStructGetData($tSCROLLINFO, "nMax"))
    MemoWrite("nTrackPos: " & DllStructGetData($tSCROLLINFO, "nTrackPos"))

    DllStructSetData($tSCROLLINFO, "cbSize", DllStructGetSize($tSCROLLINFO))
    DllStructSetData($tSCROLLINFO, "fMask", $SIF_ALL)
    _GUIScrollBars_GetScrollInfo($hGUI, $SB_VERT, $tSCROLLINFO)
    MemoWrite(@CRLF & "Vertical" & @CRLF & "--------------------------------------")
    MemoWrite("nPage....: " & DllStructGetData($tSCROLLINFO, "nPage"))
    MemoWrite("nPos.....: " & DllStructGetData($tSCROLLINFO, "nPos"))
    MemoWrite("nMin.....: " & DllStructGetData($tSCROLLINFO, "nMin"))
    MemoWrite("nMax.....: " & DllStructGetData($tSCROLLINFO, "nMax"))
    MemoWrite("nTrackPos: " & DllStructGetData($tSCROLLINFO, "nTrackPos"))

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Écrit une ligne dans le contrôle mémo
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite