UDF > GUI > GuiToolbar >

_GUICtrlToolbar_LoadBitmap

Ajoute une image bitmap à la liste d'image, à partir d'un fichier

#include <GuiToolbar.au3>
_GUICtrlToolbar_LoadBitmap ( $hWnd, $sFileName )

Paramètres

$hWnd Handle de la barre d'outils
$sFileName Chemin d'accès complet vers le fichier bitmap

Valeur de retour

Succès: Retourne l'index, de base 0, de la nouvelle image.
Échec: Retourne -1.

En relation

_GUICtrlToolbar_AddBitmap

Exemple

#include <GUIConstantsEx.au3>
#include <GuiToolbar.au3>

Example()

Func Example()
    Local $hGUI, $hToolbar
    Local Enum $e_idRed = 1000, $e_idGreen, $e_idBlue
    Local $sWow64 = ""
    If @AutoItX64 Then $sWow64 = "\Wow6432Node"
    Local $sPath = RegRead("HKEY_LOCAL_MACHINE\SOFTWARE" & $sWow64 & "\AutoIt v3\AutoIt", "InstallDir") & "\Examples\GUI\Advanced\Images"

    ; Crée une GUI
    $hGUI = GUICreate("Toolbar", 400, 300)
    $hToolbar = _GUICtrlToolbar_Create($hGUI)
    GUISetState(@SW_SHOW)

    ; Ajoute des bitmaps
    _GUICtrlToolbar_LoadBitmap($hToolbar, $sPath & "\red.bmp")
    _GUICtrlToolbar_LoadBitmap($hToolbar, $sPath & "\green.bmp")
    _GUICtrlToolbar_LoadBitmap($hToolbar, $sPath & "\blue.bmp")

    ; Ajoute des boutons
    _GUICtrlToolbar_AddButton($hToolbar, $e_idRed, 0)
    _GUICtrlToolbar_AddButton($hToolbar, $e_idGreen, 1)
    _GUICtrlToolbar_AddButton($hToolbar, $e_idBlue, 2)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example