UDF > GUI > GuiToolbar >


_GUICtrlToolbar_AddBitmap

Ajoute des images à la liste d'image du contrôle Toolbar

#include <GuiToolbar.au3>
_GUICtrlToolbar_AddBitmap ( $hWnd, $iButtons, $hInst, $iID )

Paramètres

$hWnd Handle du contrôle
$iButtons Nombre d'images de bouton dans le bitmap
$hInst Handle de l'instance du module avec le fichier exécutable qui contient une ressource bitmap.
Pour utiliser les handles de bitmap à la place des ID de ressources, définissez ce paramètre à 0. Vous pouvez ajouter des bitmaps de bouton définis par le système à la liste en spécifiant -1 pour le membre $hInst et l'une des valeurs suivantes pour le membre $iID:
    $IDB_STD_LARGE_COLOR - Ajoute de grands bitmaps en couleur, standards
    $IDB_STD_SMALL_COLOR - Ajoute de petits bitmaps en couleur, standards
    $IDB_VIEW_LARGE_COLOR - Ajoute de grands bitmaps en couleur, avec apparence
    $IDB_VIEW_SMALL_COLOR - Ajoute de petits bitmaps en couleurs, avec apparence
$iID Si $hInst est 0, définissez ce membre sur le handle du bitmap avec les images de bouton.
Sinon, définissez-le avec l'identifiant de ressource du bitmap avec les images de bouton.
Voici les ID de ressource des bitmaps standards et d'apparence:
    $STD_COPY - Image du bouton Copier
    $STD_CUT - Image Couper
    $STD_DELETE - Image Supprimer
    $STD_FILENEW - Image Nouveau Fichier
    $STD_FILEOPEN - Image Ouvrir Fichier
    $STD_FILESAVE - Image Enregistrer Fichier
    $STD_FIND - Image Chercher
    $STD_HELP - Image Aide
    $STD_PASTE - Image Coller
    $STD_PRINT - Image Imprimer
    $STD_PRINTPRE - Image Aperçu Impression
    $STD_PROPERTIES - Image Propriétés
    $STD_REDOW - Image Refaire
    $STD_REPLACE - Image Remplacer
    $STD_UNDO - Image Défaire
    $VIEW_DETAILS - Image pour une vue en détail
    $VIEW_LARGEICONS - Image pour une vue en grandes icônes
    $VIEW_LIST - Image pour une vue en liste
    $VIEW_SMALLICONS - Image pour une vue en petites icônes.
    $VIEW_SORTDATE - Image pour une vue trié par date.
    $VIEW_SORTNAME - Image pour une vue trié par nom.
    $VIEW_SORTSIZE - Image pour une vue trié par taille.
    $VIEW_SORTTYPE - Image pour une vue trié par type.

Valeur de retour

Succès: Retourne l'index, de base 0, de la première nouvelle image.
Échec: Retourne -1.

En relation

_GUICtrlToolbar_LoadBitmap

Exemple

#include <GUIConstantsEx.au3>
#include <GuiToolbar.au3>
#include <WinAPIConstants.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $hGUI, $hToolbar
    Local Enum $e_idNew = 1000, $e_idOpen, $e_idSave, $idHelp

    ; Crée une GUI
    $hGUI = GUICreate("Toolbar", 400, 300)
    $hToolbar = _GUICtrlToolbar_Create($hGUI)
    GUISetState(@SW_SHOW)

    ; Ajoute des bitmaps system standards
    _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)

    ; Ajoute des boutons
    _GUICtrlToolbar_AddButton($hToolbar, $e_idNew, $STD_FILENEW)
    _GUICtrlToolbar_AddButton($hToolbar, $e_idOpen, $STD_FILEOPEN)
    _GUICtrlToolbar_AddButton($hToolbar, $e_idSave, $STD_FILESAVE)
    _GUICtrlToolbar_AddButtonSep($hToolbar)
    _GUICtrlToolbar_AddButton($hToolbar, $idHelp, $STD_HELP)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example