UDF > GUI > GuiReBar >

_GUICtrlRebar_AddToolBarBand

Ajoute un nouveau ruban avec un Toolbar dans un contrôle Rebar

#include <GuiReBar.au3>
_GUICtrlRebar_AddToolBarBand ( $hWndRebar, $hWndToolbar [, $sText = "" [, $iIndex = -1 [, $iStyle = -1]]] )

Paramètres

$hWndRebar Handle du contrôle Rebar
$hWndToolbar Handle du contrôle ToolBar à ajouter
$sText [optionnel] Texte à afficher dans le ruban
$iIndex [optionnel] Index, de base 0, de l'endroit où le ruban sera inséré.
Si vous définissez ce paramètre à -1, le contrôle ajoute le nouveau ruban en dernière position
$iStyle [optionnel] Flags qui spécifient le style de ruban. Cette valeur peut être une combinaison des valeurs suivantes:
    $RBBS_BREAK - Le ruban est sur une nouvelle ligne.
    $RBBS_CHILDEDGE - Le ruban a un bord en haut et en bas de la fenêtre enfant.
    $RBBS_FIXEDBMP - L'image bitmap d'arrière-plan ne bouge pas lorsque la bande est redimensionnée.
    $RBBS_FIXEDSIZE - Le ruban ne peut pas être redimensionné. Avec ce style, la poignée de redimensionnement n'est pas affiché sur la bande.
    $RBBS_GRIPPERALWAYS - Version 4.71. Le ruban aura toujours une poignée de redimensionnement, même s'il est le seul ruban de la barre Rebar.
    $RBBS_HIDDEN - Le ruban ne sera pas visible.
    $RBBS_NOGRIPPER - Version 4.71. Le ruban n'aura jamais une poignée de redimensionnement, même s'il y a plusieurs un ruban dans la Rebar.
    $RBBS_USECHEVRON - Version 5.80. Affiche un bouton chevron si le ruban est plus petit que cxIdeal.
    $RBBS_VARIABLEHEIGHT - Version 4.71. Le ruban peut être redimensionné par le contrôle Rebar; cyIntegral et cyMaxChild affectent la façon dont le Rebar va redimensionner le ruban.
    $RBBS_NOVERT - N'affiche pas en position verticale.
    $RBBS_USECHEVRON - Affiche un bouton déroulant.
    $RBBS_HIDETITLE - Garde le titre du ruban caché.
    $RBBS_TOPALIGN - Garde le ruban dans la rangée du haut.

Valeur de retour

Succès: Retourne True.
Échec: Retourne False.

En relation

_GUICtrlRebar_AddBand, _GUICtrlRebar_DeleteBand

Exemple

#include <GUIConstantsEx.au3>
#include <GuiReBar.au3>
#include <GuiToolbar.au3>
#include <WinAPIConstants.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $hGui, $idBtnExit, $hToolbar, $hReBar, $idInput, $msg
    Local Enum $e_idNew = 1000, $e_idOpen, $e_idSave, $idHelp

    $hGui = GUICreate("Rebar", 400, 396, -1, -1, BitOR($WS_MINIMIZEBOX, $WS_CAPTION, $WS_POPUP, $WS_SYSMENU, $WS_MAXIMIZEBOX))

    ; Crée un contrôle rebar
    $hReBar = _GUICtrlRebar_Create($hGui, BitOR($CCS_TOP, $WS_BORDER, $RBS_VARHEIGHT, $RBS_AUTOSIZE, $RBS_BANDBORDERS))

    ; Crée un toolbar pour le placer dans le rebar
    $hToolbar = _GUICtrlToolbar_Create($hGui, BitOR($TBSTYLE_FLAT, $CCS_NORESIZE, $CCS_NOPARENTALIGN))

    ; Ajoute des bitmaps système standards
    Switch _GUICtrlToolbar_GetBitmapFlags($hToolbar)
        Case 0
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_SMALL_COLOR)
        Case 2
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
    EndSwitch

    ; Ajoute des boutons
    _GUICtrlToolbar_AddButton($hToolbar, $e_idNew, $STD_FILENEW)
    _GUICtrlToolbar_AddButton($hToolbar, $e_idOpen, $STD_FILEOPEN)
    _GUICtrlToolbar_AddButton($hToolbar, $e_idSave, $STD_FILESAVE)
    _GUICtrlToolbar_AddButtonSep($hToolbar)
    _GUICtrlToolbar_AddButton($hToolbar, $idHelp, $STD_HELP)

    ; Crée un inputbox pour le placer dans le rebar
    $idInput = GUICtrlCreateInput("Input control", 0, 0, 120, 20)

    ; Ajoute un ruban avec le contrôle inputbox
    _GUICtrlRebar_AddBand($hReBar, GUICtrlGetHandle($idInput), 120, 200, "Name:")

    ; Ajoute un ruban avec le contrôle toolbar au début du rebar
    _GUICtrlRebar_AddToolBarBand($hReBar, $hToolbar, "", 0)

    $idBtnExit = GUICtrlCreateButton("Exit", 150, 360, 100, 25)
    GUISetState(@SW_SHOW)

    Do
        $msg = GUIGetMsg()
    Until $msg = $GUI_EVENT_CLOSE Or $msg = $idBtnExit
EndFunc   ;==>Example