UDF > GUI > GuiListView >


_GUICtrlListView_InsertItem

Insère un nouvel élément dans le contrôle

#include <GuiListView.au3>
_GUICtrlListView_InsertItem ( $hWnd, $sText [, $iIndex = -1 [, $iImage = -1 [, $iParam = 0]]] )

Paramètres

$hWnd ID/handle du contrôle
$sText Texte de l'élément. S'il est défini à -1, le texte de l'élément est défini par l'intermédiaire du message de notification $LVN_GETDISPINFO.
$iIndex [optionnel] Index, de base 0, auquel le nouvel élément doit être inséré.
Si cette valeur est supérieure au nombre d'éléments actuellement contenus dans le contrôle, le nouvel élément sera ajouté à la fin de la liste et affecté de l'index correct.
$iImage [optionnel] Index, compé à partir de 0, de l'icône de l'élément dans la liste d'images du contrôle
$iParam [optionnel] Application Defined Data

Valeur de retour

Succès: Retourne l'index du nouvel élément.
Échec: Retourne -1.

Remarques

Vous ne pouvez pas utiliser cette fonction pour insérer des sous-éléments. Utilisez _GUICtrlListView_SetItemText() pour insérer des sous-éléments.

Comme AutoIt utilise le paramètre $iParam pour stocker le controlID des éléments ListView créés de façon native, cette valeur doit être suffisamment élevé pour des éléments créés avec l'UDF afin d'éviter tout conflit avec des contrôles existants - une valeur de départ de 1000 est recommandé.

En relation

_GUICtrlListView_SetItemText

Exemple

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>

Example()

Func Example()
    Local $idListview

    GUICreate("ListView Insert Item", 400, 300)
    $idListview = GUICtrlCreateListView("", 2, 2, 394, 268)
    GUISetState(@SW_SHOW)

    ; Insère des colonnes
    _GUICtrlListView_InsertColumn($idListview, 0, "Column 1", 100)

    ; Ajoute des éléments
    _GUICtrlListView_InsertItem($idListview, "Item 1", 0)
    _GUICtrlListView_InsertItem($idListview, "Item 2", 1)
    _GUICtrlListView_InsertItem($idListview, "Item 3", 1)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    GUIDelete()
EndFunc   ;==>Example