UDF > GUI > GuiListView >


_GUICtrlListView_GetTopIndex

Obtient l'index de l'élément visible le plus haut quand le mode d'affichage est liste ou rapport

#include <GuiListView.au3>
_GUICtrlListView_GetTopIndex ( $hWnd )

Paramètre

$hWnd ID/handle du contrôle

Valeur de retour

Retourne l'index de l'élément, de base 0.
    Zéro si le contrôle ListView est en mode icône ou petite icône.

Exemple

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $idListview

    GUICreate("ListView Get Top Index", 400, 300)
    $idListview = GUICtrlCreateListView("", 2, 2, 394, 268)
    GUISetState(@SW_SHOW)

    ; Ajoute des colonnes
    _GUICtrlListView_AddColumn($idListview, "Items", 100)

    ; Ajoute des éléments
    _GUICtrlListView_BeginUpdate($idListview)
    For $iI = 1 To 100
        _GUICtrlListView_AddItem($idListview, "Item " & $iI)
    Next
    _GUICtrlListView_EndUpdate($idListview)

    ; Sélectionne l'élément 50
    _GUICtrlListView_SetItemSelected($idListview, 49)
    _GUICtrlListView_EnsureVisible($idListview, 49)
    MsgBox($MB_SYSTEMMODAL, "Information", "Top Index: " & _GUICtrlListView_GetTopIndex($idListview))

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    GUIDelete()
EndFunc   ;==>Example